Delegation PoC

contracts/staking/ERC20TokenStakingManager.sol

@@ -83,16 +83,35 @@ contract ERC20TokenStakingManager is
         $._token = token;
     }
 
+    /**
+     * @notice Begins the validator registration process. Locks the configured ERC20 in the contract as the stake.
+     * @param stakeAmount The amount to be staked.
+     * @param nodeID The node ID of the validator being registered.
+     * @param registrationExpiry The Unix timestamp after which the reigistration is no longer valid on the P-Chain.
+     * @param blsPublicKey The BLS public key of the validator.
+     */
     function initializeValidatorRegistration(
         uint256 stakeAmount,
         bytes32 nodeID,
         uint64 registrationExpiry,
         bytes memory blsPublicKey
-    ) external override returns (bytes32 validationID) {
+    ) external returns (bytes32 validationID) {
         uint64 weight = _processStake(stakeAmount);
         return _initializeValidatorRegistration(nodeID, weight, registrationExpiry, blsPublicKey);
     }
 
+    /**
+     * @notice Begins the delegator registration process. Locks the configured ERC20 in the contract as the delegated stake.
+     * @param validationID The ID of the validation period being delegated to.
+     * @param delegationAmount The amount to be delegated.
+     */
+    function initializeDelegatorRegistration(
+        bytes32 validationID,
+        uint256 delegationAmount
+    ) external {
+        return _initializeDelegatorRegistration(validationID, _msgSender(), delegationAmount);
+    }
+
     // Must be guarded with reentrancy guard for safe transfer from
     function _lock(uint256 value) internal virtual override returns (uint256) {
         return _getERC20StakingManagerStorage()._token.safeTransferFrom(value);

contracts/staking/NativeTokenStakingManager.sol

@@ -50,22 +50,24 @@ contract NativeTokenStakingManager is
     /**
      * @notice Begins the validator registration process. Locks the provided native asset in the contract as the stake.
      * @param nodeID The node ID of the validator being registered.
-     * @param registrationExpiry The time at which the registration is no longer valid on the P-Chain.
-     * @param signature The raw bytes of the Ed25519 signature over the concatenated bytes of
-     * [subnetID]+[nodeID]+[blsPublicKey]+[weight]+[balance]+[expiry]. This signature must correspond to the Ed25519
-     * public key that is used for the nodeID. This approach prevents nodeIDs from being unwillingly added to Subnets.
-     * balance is the minimum initial $nAVAX balance that must be attached to the validator serialized as a uint64.
-     * The signature field will be validated by the P-Chain. Implementations may choose to validate that the signature
-     * field is well-formed but it is not required.
+     * @param registrationExpiry The Unix timestamp after which the registration is no longer valid on the P-Chain.
+     * @param blsPublicKey The BLS public key of the validator.
      */
     function initializeValidatorRegistration(
         bytes32 nodeID,
         uint64 registrationExpiry,
-        bytes memory signature
+        bytes memory blsPublicKey
     ) external payable returns (bytes32) {
         uint64 weight = _processStake(msg.value);
+        return _initializeValidatorRegistration(nodeID, weight, registrationExpiry, blsPublicKey);
+    }
 
-        return _initializeValidatorRegistration(nodeID, weight, registrationExpiry, signature);
+    /**
+     * @notice Begins the delegator registration process. Locks the provided native asset in the contract as the delegated stake.
+     * @param validationID The ID of the validation period being delegated to.
+     */
+    function initializeDelegatorRegistration(bytes32 validationID) external payable {
+        return _initializeDelegatorRegistration(validationID, _msgSender(), msg.value);
     }
 
     // solhint-enable ordering

contracts/staking/PoSValidatorManager.sol

@@ -5,9 +5,12 @@
 
 pragma solidity 0.8.25;
 
-import {IPoSValidatorManager} from "./interfaces/IPoSValidatorManager.sol";
+import {
+    IPoSValidatorManager, Delegator, DelegatorStatus
+} from "./interfaces/IPoSValidatorManager.sol";
 import {PoSValidatorManagerSettings} from "./interfaces/IPoSValidatorManager.sol";
 import {ValidatorManager} from "./ValidatorManager.sol";
+import {Validator, ValidatorStatus} from "./interfaces/IValidatorManager.sol";
 import {WarpMessage} from
     "@avalabs/[email protected]/contracts/interfaces/IWarpMessenger.sol";
 import {ValidatorMessages} from "./ValidatorMessages.sol";
@@ -17,10 +20,23 @@
     // solhint-disable private-vars-leading-underscore
     /// @custom:storage-location erc7201:avalanche-icm.storage.PoSValidatorManager
     struct PoSValidatorManagerStorage {
+        /// @notice The minimum amount of stake required to be a validator.
         uint256 _minimumStakeAmount;
+        /// @notice The maximum amount of stake allowed to be a validator.
         uint256 _maximumStakeAmount;
+        /// @notice The minimum amount of time a validator must be staked for.
         uint64 _minimumStakeDuration;
+        /// @notice The reward calculator for this validator manager.
         IRewardCalculator _rewardCalculator;
+        /// @notice Maps the validationID to a mapping of delegator address to delegator information.
+        mapping(bytes32 validationID => mapping(address delegator => Delegator)) _delegatorStakes;
+        /// @notice Maps the validationID to a mapping of delegator address to pending register delegator messages.
+        mapping(bytes32 validationID => mapping(address delegator => bytes))
+            _pendingRegisterDelegatorMessages;
+        /// @notice Maps the validationID to a mapping of delegator address to pending end delegator messages.
+        mapping(bytes32 validationID => mapping(address delegator => bytes))
+            _pendingEndDelegatorMessages;
+        /// @notice Maps the validationID to the uptime of the validator.
         mapping(bytes32 validationID => uint64) _validatorUptimes;
     }
     // solhint-enable private-vars-leading-underscore
@@ -108,11 +124,9 @@
         PoSValidatorManagerStorage storage $ = _getPoSValidatorManagerStorage();
         // Lock the stake in the contract.
         uint256 lockedValue = _lock(stakeAmount);
-
-        // Ensure the stake churn doesn't exceed the maximum churn rate.
         uint64 weight = valueToWeight(lockedValue);
-        // Ensure the weight is within the valid range.
 
+        // Ensure the weight is within the valid range.
         require(
             weight >= $._minimumStakeAmount && weight <= $._maximumStakeAmount,
             "PoSValidatorManager: invalid stake amount"
@@ -130,4 +144,196 @@
 
     function _lock(uint256 value) internal virtual returns (uint256);
     function _unlock(uint256 value, address to) internal virtual;
+
+    function _initializeDelegatorRegistration(
+        bytes32 validationID,
+        address delegator,
+        uint256 delegationAmount
+    ) internal nonReentrant {
+        uint64 weight = valueToWeight(_lock(delegationAmount));
+        PoSValidatorManagerStorage storage $ = _getPoSValidatorManagerStorage();
+
+        // Ensure the validation period is active
+        Validator memory validator = _getValidator(validationID);
+        require(
+            validator.status == ValidatorStatus.Active, "PoSValidatorManager: validator not active"
+        );
+
+        // Ensure the delegator is not already registered
+        require(
+            $._delegatorStakes[validationID][delegator].weight == 0,
+            "PoSValidatorManager: delegator already registered"
+        );
+
+        _checkAndUpdateChurnTracker(weight);
+
+        // Update the validator weight
+        validator.weight += weight;
+        _setValidator(validationID, validator);
+
+        // Submit the message to the Warp precompile.
+        uint64 nonce = _getAndIncrementNonce(validationID);
+        bytes memory setValidatorWeightPayload = ValidatorMessages
+            .packSetSubnetValidatorWeightMessage(validationID, nonce, validator.weight);
+        $._pendingRegisterDelegatorMessages[validationID][delegator] = setValidatorWeightPayload;
+        bytes32 messageID = WARP_MESSENGER.sendWarpMessage(setValidatorWeightPayload);
+
+        // Store the delegator information
+        $._delegatorStakes[validationID][delegator] = Delegator({
+            status: DelegatorStatus.PendingAdded,
+            weight: weight,
+            startedAt: 0,
+            endedAt: 0,
+            startingNonce: nonce,
+            endingNonce: 0
+        });
+
+        emit DelegatorAdded({
+            validationID: validationID,
+            setWeightMessageID: messageID,
+            delegator: delegator,
+            delegatorWeight: weight,
+            validatorWeight: validator.weight,
+            nonce: nonce
+        });
+    }
+
+    function resendDelegatorRegistration(bytes32 validationID, address delegator) external {
+        _checkPendingRegisterDelegatorMessages(validationID, delegator);
+        PoSValidatorManagerStorage storage $ = _getPoSValidatorManagerStorage();
+        // Submit the message to the Warp precompile.
+        WARP_MESSENGER.sendWarpMessage($._pendingRegisterDelegatorMessages[validationID][delegator]);
+    }
+
+    function completeDelegatorRegistration(uint32 messageIndex, address delegator) external {
+        PoSValidatorManagerStorage storage $ = _getPoSValidatorManagerStorage();
+
+        // Unpack the Warp message
+        WarpMessage memory warpMessage = _getPChainWarpMessage(messageIndex);
+        (bytes32 validationID, uint64 nonce,) =
+            ValidatorMessages.unpackSubnetValidatorWeightUpdateMessage(warpMessage.payload);
+        _checkPendingRegisterDelegatorMessages(validationID, delegator);
+        delete $._pendingRegisterDelegatorMessages[validationID][delegator];
+
+        Validator memory validator = _getValidator(validationID);
+
+        // The received nonce should be no greater than the highest sent nonce
+        require(validator.messageNonce >= nonce, "PoSValidatorManager: invalid nonce");
+        // It should also be greater than or equal to the delegator's starting nonce
+        require(
+            $._delegatorStakes[validationID][delegator].startingNonce <= nonce,
+            "PoSValidatorManager: nonce does not match"
+        );
+
+        require(
+            $._delegatorStakes[validationID][delegator].status == DelegatorStatus.PendingAdded,
+            "PoSValidatorManager: delegator not pending added"
+        );
+        // Update the delegator status
+        $._delegatorStakes[validationID][delegator].status = DelegatorStatus.Active;
+        $._delegatorStakes[validationID][delegator].startedAt = uint64(block.timestamp);
+
+        emit DelegatorRegistered({
+            validationID: validationID,
+            delegator: delegator,
+            nonce: nonce,
+            startTime: block.timestamp
+        });
+    }
+
+    function initializeEndDelegation(bytes32 validationID) external {
+        PoSValidatorManagerStorage storage $ = _getPoSValidatorManagerStorage();
+
+        // Ensure the delegator is active
+        Delegator memory delegator = $._delegatorStakes[validationID][_msgSender()];
+        require(
+            delegator.status == DelegatorStatus.Active, "PoSValidatorManager: delegator not active"
+        );
+        uint64 nonce = _getAndIncrementNonce(validationID);
+        delegator.status = DelegatorStatus.PendingRemoved;
+        delegator.endedAt = uint64(block.timestamp);
+        delegator.endingNonce = nonce;
+
+        $._delegatorStakes[validationID][_msgSender()] = delegator;
+
+        Validator memory validator = _getValidator(validationID);
+        require(validator.weight > delegator.weight, "PoSValidatorManager: Invalid weight");
+        validator.weight -= delegator.weight;
+        _setValidator(validationID, validator);
+
+        // Submit the message to the Warp precompile.
+        bytes memory setValidatorWeightPayload = ValidatorMessages
+            .packSetSubnetValidatorWeightMessage(validationID, nonce, validator.weight);
+        $._pendingEndDelegatorMessages[validationID][_msgSender()] = setValidatorWeightPayload;
+        bytes32 messageID = WARP_MESSENGER.sendWarpMessage(setValidatorWeightPayload);
+
+        emit DelegatorRemovalInitialized({
+            validationID: validationID,
+            setWeightMessageID: messageID,
+            delegator: _msgSender(),
+            validatorWeight: validator.weight,
+            nonce: nonce,
+            endTime: block.timestamp
+        });
+    }
+
+    function resendEndDelegation(bytes32 validationID, address delegator) external {
+        _checkPendingEndDelegatorMessage(validationID, delegator);
+        PoSValidatorManagerStorage storage $ = _getPoSValidatorManagerStorage();
+        WARP_MESSENGER.sendWarpMessage($._pendingEndDelegatorMessages[validationID][delegator]);
+    }
+
+    function completeEndDelegation(uint32 messageIndex, address delegator) external {
+        PoSValidatorManagerStorage storage $ = _getPoSValidatorManagerStorage();
+
+        // Unpack the Warp message
+        WarpMessage memory warpMessage = _getPChainWarpMessage(messageIndex);
+        (bytes32 validationID, uint64 nonce,) =
+            ValidatorMessages.unpackSubnetValidatorWeightUpdateMessage(warpMessage.payload);
+        _checkPendingEndDelegatorMessage(validationID, delegator);
+        delete $._pendingEndDelegatorMessages[validationID][delegator];
+
+        Validator memory validator = _getValidator(validationID);
+        // The received nonce should be no greater than the highest sent nonce
+        require(validator.messageNonce >= nonce, "PoSValidatorManager: invalid nonce");
+        // It should also be greater than or equal to the delegator's ending nonce
+        require(
+            $._delegatorStakes[validationID][delegator].endingNonce <= nonce,
+            "PoSValidatorManager: nonce does not match"
+        );
+
+        require(
+            $._delegatorStakes[validationID][delegator].status == DelegatorStatus.PendingRemoved,
+            "PoSValidatorManager: delegator not pending added"
+        );
+
+        // Update the delegator status
+        $._delegatorStakes[validationID][delegator].status = DelegatorStatus.Completed;
+
+        emit DelegationEnded(validationID, delegator, nonce);
+    }
+
+    function _checkPendingEndDelegatorMessage(
+        bytes32 validationID,
+        address delegator
+    ) private view {
+        PoSValidatorManagerStorage storage $ = _getPoSValidatorManagerStorage();
+        require(
+            $._pendingEndDelegatorMessages[validationID][delegator].length > 0
+                && $._delegatorStakes[validationID][delegator].status == DelegatorStatus.PendingRemoved,
+            "PoSValidatorManager: delegator removal not pending"
+        );
+    }
+
+    function _checkPendingRegisterDelegatorMessages(
+        bytes32 validationID,
+        address delegator
+    ) private view {
+        PoSValidatorManagerStorage storage $ = _getPoSValidatorManagerStorage();
+        require(
+            $._pendingRegisterDelegatorMessages[validationID][delegator].length > 0
+                && $._delegatorStakes[validationID][delegator].status == DelegatorStatus.PendingAdded,
+            "PoSValidatorManager: delegator registration not pending"
+        );
+    }
 }