grammar.nlg

%
    ~prefix? %main ~suffix?
    %greeting
    %thanks

%main=
    %sequence
    %if
    %timer
    %alarm
#    %reminder

# TODO: %if vs. %when
%if
    ~if %condition then %sequence
    %sequence ~if %condition
    ~if %condition %alert
    %alert ~if %condition

%timer
    %sequence %time
    %time %sequence

%alarm
    ~set an alarm %time

%reminder
    remind me to $message

%sequence
    ~please? %action
    ~please? %action ~also ~please? %action
    ~please? %action ~also ~please? %action ~also ~please? %action
    ~please? %action ~also ~please? %action ~also ~please? %action ~also ~please? %action
#   [~please %action ~also]

%time=
    %relative_time
    %absolute_time

%relative_time
    ~in $number %time_unit

%absolute_time
    ~at $time

%condition
    %getValue %compare $number

%compare=
    ~is
    ~is %operator

%getValue
    %getPrice
    %getTemperature

%action
    %getLightState
    %getSwitchState
    %getPrice
    %getTemperature
    %setLightState
    %setSwitchState
    %setTemperature
    %setVolume
    %playMusic
#    %sendMessage

# Specific commands
# ---------------------------------------------------------

%alert
    %message_type me
    ~send a %message_type
    ~send me a %message_type
#    let me know (%message_type=@chat)

%message
    ~send a %message_type to $person
    %message_type $person
    ~send $person a %message_type
    tell $person $message

%message_type
    @sms
    @call
    @email
    @chat

@sms
    sms
    text

@email
    email
    e-mail
    mail

@call
    call
    phone call
    ring
    
@chat
    chat
    message
    ping

~send
    send
    deliver
    shoot
    give

%getLightState
    ~get? the %light_name state

%getSwitchState
    ~get? the %switch_name state

%getTemperature
    ~get? the temperature in the %room_name
    ~get? the %room_name temperature

%getPrice
    ~get? price of %asset
    ~get? %asset price

%setLightState
    ~set %light_name %light_state
    ~set %light_state %light_name

%setSwitchState
    ~set %switch_name %switch_state
    ~set %switch_state %switch_name

%setTemperature
    ~set the %room_name temperature to $temperature
    ~set the temperature of %room_name to $temperature

%setVolume
    ~set the volume %volume_state

%playMusic
    play $song_name
    play ~something_by $artist_name

%greeting
    ~greeting

%thanks
    ~thanks

# Synonyms
# ---------------------------------------------------------

~if
    if
    when
    as soon as

~is
    is
    goes
    gets
    becomes

~in
    in

~at
    at

~set
    set
    turn
    make
    change

~get
    get
    tell me
    what is
    what's the
    gimme

~prefix
    um
    uh
    ~greeting
    ~greeting ~please

~greeting
    hi
    hello there maia
    hey maia
    hey um
    heya
    yo
    oh hi
    oh hey there

~please
    please
    pls
    plox
    plx
    pretty please
    could you
    could you please
    you oughta
    you better
    you should ~definitely
    ~definitely
    just like
    ok so
    could ya
    would ya

~definitely
    definitely
    totally
    def
    totes

~suffix
    ~thanks
    ~please
    ~alright
    ~lol

~thanks
    thank you
    thanks
    thx
    thank you very much
    thanks maia
    thank you maia

~alright
    alright
    aight
    you got it
    you understand
    or else
    you noob

~lol
    lol
    haha
    wtf
    omg

~also
    and
    also
    then
    next
    and also
    then also
    and then
    and next
    then next
    and ~please could you also

~something_by
    something by
    some
    some music by
    a song from
    shit by
    some shit from

# Values
# ---------------------------------------------------------

$message
    get the laundry
    do the dishes
    buy soap
    go to sleep
    milk is in the fridge
    ~i_ll be ~timing

~i_ll
    i will
    i'll
    i shall
    i might

~timing
    late
    early
    on time
    there soon
    there at $time

%operator
    @equal
    @greater_than
    @less_than

@equal
    equal to

@greater_than
    greater than
    bigger than
    above

@less_than
    less than
    smaller than
    below
    under

%asset
    @btc
    @eth
    $stock

@btc
    bitcoin
    btc

@eth
    ethereum
    eth

$stock
    tesla
    microsoft
    apple
    amazon
    spacex
    trulia

%room_name
    @office
    @living_room
    @bedroom
    @basement
    @kitchen
    @bathroom
    @outside
    
@office
    office
    
@living_room
    living room
    den
    family room
    
@bedroom
    bedroom
    my room
    
@basement
    basement
    downstairs
    
@kitchen
    kitchen
    
@bathroom
    bathroom
    shitter
    loo
    
@outside
    outside
    outdoor
    outdoors

%light_name
    @office_light
    @living_room_light
    @bedroom_lights
    @basement_light
    @kitchen_light
    @bathroom_light
    @outside_light
    @all_lights

@office_light
    the office light
    the light in the office

@living_room_light
    the living room light
    the light in the living room
    the light in the den

@bedroom_lights
    the bedroom lights
    my lights

@basement_light
    the basement light

@kitchen_light
    the kitchen light

@bathroom_light
    the bathroom light

@outside_light
    the outside light

@all_lights
    all the lights
    every light
    all lights
    everything

%switch_name
    @tea_switch
    @coffee_switch

@tea_switch
    the tea switch
    the tea
    the hot plate

@coffee_switch
    the coffee
    the coffee pot

%light_state
    @on
    @off
    @up
    @down
    @high
    @low
    $color

%switch_state
    @on
    @off

%volume_state
    @on
    @off
    @up
    @down
    to $number

@on
    on

@off
    off

@up
    up
    higher
    brighter

@down
    down
    lower
    darker

@high
    high
    bright

@low
    low
    dark

$color
    red
    green
    blue
    yellow
    purple
    white
    orange

# Numbers and time

$number
    $digits

$digits=
    $digit
    $digit $digit
    $digit $digit $digit
    $digit $digit $digit $digit

$digit=
    0
    1
    2
    3
    4
    5
    6
    7
    8
    9

%time_unit
    @seconds
    @minutes
    @hours
    @days

@seconds
    seconds
    secs
    sec
    s

@minutes
    minutes
    mins
    min
    m

@hours
    hours
    hour
    hrs
    hr
    h

@days
    days
    day
    d

$temperature
    $digits ~f_c?

~f_c
    f
    c

$time
    $hour : $minute ~am_pm?

~am_pm
    am
    pm

$hour
    $digit
    $digit $digit

$minute
    0 $digit
    $digit $digit

# Music
# TODO: Import or generate

$artist_name
    Isigin Yansimasi
    Duman
    Placebo
    Kurban
    Dolapdere Big Gang
    Korn
    The Cure
    The Gathering
    Athena
    Badem
    Hayko Cepkin
    Aerosmith
    Oasis
    Muse
    Skrillex
    Whitesnake
    Blonde Redhead
    The White Stripes
    Maroon 5
    Natalie Imbruglia
    Beirut
    lhan Sesen
    Morrissey
    Jay-Jay Johanson
    Wet Wet Wet
    Yakup
    Ufuk Yildirim
    Deniz Seki
    Elsiane
    Nev
    Reha
    Nelly Furtado
    Massive Attack
    Bon Jovi
    Diken
    Sezen Aksu
    Ceza
    Agua de Annique
    Berlin
    Coldplay
    Sebnem Ferah
    Radiohead
    Pinhani
    Vega
    Kenan Dogulu
    Reha Falay
    Muse

$song_name
    All I Have To Do Is Dream
    Love It When You Call
    Chelsea Dagger
    New Album Version
    Iris
    Hate To Say I Told You So
    Remaster
    Shout
    Summer Breeze
    Blame It On The Boogie
    Can You Feel It
    A Town Called Malice
    Human
    Somebody Told Me
    When You Were Young
    Louie Louie
    All Day And All Of The Night
    Lola
    Mono Single Version
    Sunny Afternoon
    Waterloo Sunset
    You Really Got Me
    My Sharona
    Naive
    Seaside
    She Moves In Her Own Way
    There She Goes
    Time For Heroes
    Jizz In My Pants
    I Just Had Sex
    Single Version
    Album Version With Introduction
    Love Machine
    Daydream Believer
    Theme From
    Any Dream Will Do
    Love Train
    Every Breath You Take
    Such Great Heights
    Breathe
    Firestarter
    Funky Shit
    Omen
    Out Of Space
    Smack My Bitch Up
    Voodoo People
    Many Shades Of Black
    Radio Edit
    Unchained Melody
    Gimme Shelter
    Paint It Black
    Sympathy For The Devil
    Under My Thumb
    Be My Baby
    Radio Edit
    You Got The Love
    Golden Brown
    Peaches
    Dry Your Eyes
    Fit But You Know It
    Last Nite
    Someday
    The Modern Age
    Under Cover Of Darkness
    Apache
    Rappers Delight
    Where Did Our Love Go
    Sweet Disposition
    My Girl
    Shut Up and Let Me Go
    Happy Together
    Turning Japanese
    I Shot The Sheriff
    Seven Nation Army
    Remixed Version
    Original Album Version
    Original Mono Version
    Original Album Version
    For Your Love
    Heart Full Of Soul
    Valerie
    Jailbreak
    The Boys Are Back In Town
    The Lion Sleeps Tonight
    The Way I Are
    The Best
    Pass Out
    Delilah
    Sexbomb