-
Notifications
You must be signed in to change notification settings - Fork 1
/
PredictDotLoan.sol
1565 lines (1300 loc) · 58.4 KB
/
PredictDotLoan.sol
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
// SPDX-License-Identifier: MIT
pragma solidity 0.8.25;
import {AccessControl} from "@openzeppelin/contracts/access/AccessControl.sol";
import {EIP712} from "@openzeppelin/contracts/utils/cryptography/EIP712.sol";
import {SignatureChecker} from "@openzeppelin/contracts/utils/cryptography/SignatureChecker.sol";
import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import {IERC20} from "@openzeppelin/contracts/interfaces/IERC20.sol";
import {ERC1155Holder} from "@openzeppelin/contracts/token/ERC1155/utils/ERC1155Holder.sol";
import {Pausable} from "@openzeppelin/contracts/utils/Pausable.sol";
import {ReentrancyGuard} from "@openzeppelin/contracts/utils/ReentrancyGuard.sol";
import {InterestLib} from "./libraries/InterestLib.sol";
import {NegRiskIdLib} from "./libraries/NegRiskIdLib.sol";
import {CalculatorHelper} from "./libraries/CalculatorHelper.sol";
import {IConditionalTokens} from "./interfaces/IConditionalTokens.sol";
import {IPredictDotLoan} from "./interfaces/IPredictDotLoan.sol";
import {ICTFExchange, Order, Side} from "./interfaces/ICTFExchange.sol";
import {IUmaCtfAdapter} from "./interfaces/IUmaCtfAdapter.sol";
import {INegRiskAdapter} from "./interfaces/INegRiskAdapter.sol";
import {console2} from "forge-std/console2.sol";
/**
* @title PredictDotLoan
* @notice PredictDotLoan matches lenders and borrowers
* of conditional tokens traded on predict.fun's CTF exchange.
* @author predict.fun protocol team
*/
contract PredictDotLoan is AccessControl, EIP712, ERC1155Holder, IPredictDotLoan, Pausable, ReentrancyGuard {
using SafeERC20 for IERC20;
using InterestLib for uint256;
/**
* @notice Refinancers are allowed to refinance loans on behalf of borrowers.
*/
bytes32 private constant REFINANCIER_ROLE = keccak256("REFINANCIER_ROLE");
/**
* @notice Max interest rate per second is 10,000% APY
*/
uint256 private constant MAX_INTEREST_RATE_PER_SECOND = InterestLib.ONE + InterestLib.TEN_THOUSAND_APY;
/**
* @notice Auction duration after a loan is called
*/
uint256 private constant AUCTION_DURATION = 1 days;
/**
* @notice The maximum protocol fee is 2%
*/
uint256 private constant MAXIMUM_PROTOCOL_FEE_BASIS_POINTS = 200;
/**
* @notice predict.fun CTF exchange
*/
ICTFExchange public immutable CTF_EXCHANGE;
/**
* @notice predict.fun neg risk CTF exchange
*/
ICTFExchange public immutable NEG_RISK_CTF_EXCHANGE;
/**
* @notice predict.fun The only loan token allowed is the CTF exchange's collateral
*/
IERC20 private immutable LOAN_TOKEN;
/**
* @notice Conditional tokens that can be used as collateral
*/
IConditionalTokens private immutable CTF;
/**
* @notice Binary outcome UMA CTF adapter
*/
address public immutable UMA_CTF_ADAPTER;
/**
* @notice Neg risk UMA CTF adapter
*/
address public immutable NEG_RISK_UMA_CTF_ADAPTER;
/**
* @notice Neg risk adapter
*/
INegRiskAdapter private immutable NEG_RISK_ADAPTER;
/**
* @notice Proposals can be partially fulfilled. This mapping keeps track of the proposal's fulfilled amount.
* The key is the hash of the user address, salt, and proposal type.
*/
mapping(bytes32 key => Fulfillment) private fulfillments;
/**
* @notice Proposals can be cancelled. This mapping keeps track of a user's salts that have been cancelled.
* Each salt can be used for exactly one loan offer and one borrow request.
* Partially fulfilled salts can be cancelled but it does not affect already fulfilled amounts.
*/
mapping(address user => mapping(uint256 salt => SaltCancellationStatus status)) public saltCancellations;
/**
* @notice Nonces are used to allow batch cancellations of loan offers and borrowing requests.
*/
mapping(address user => Nonces) public nonces;
/**
* @notice Each loan has a unique ID. With each new loan created, this counter is incremented.
*/
uint256 private nextLoanId = 1;
mapping(uint256 loanId => Loan loan) public loans;
/**
* @notice positionQuestion keeps track of the association between a position and a question.
* Each position should belong to exactly one question, there cannot be two positions
* with the same ID that map to different questions
*/
mapping(uint256 positionId => bytes32 questionId) private positionQuestion;
/**
* @notice Users who do not enable auto-refinancing will not have their loans auto-refinanced
* by a refinancier when there is a better loan offer available.
*/
mapping(address user => uint256 enableAutoRefinancing) public autoRefinancingEnabled;
/**
* @notice The protocol charges a fee on each loan. The fee goes to this address.
*/
address private protocolFeeRecipient;
/**
* @notice The protocol charges a fee on each loan. The fee is a percentage of the loan amount.
*/
uint8 private protocolFeeBasisPoints;
/**
* @notice The minimum order fee rate for order fills. The difference between the order fee rate and the minimum order fee rate
* is refunded to the maker. It behaves similarly to the makerFeeRate in
* https://github.com/Polymarket/exchange-fee-module/blob/main/src/FeeModule.sol#L45.
*/
uint16 private minimumOrderFeeRate;
/**
* @dev LOAN_TOKEN, CTF and NEG_RISK_ADAPTER are private. We have to lower the contract size
* and by having CTF_EXCHANGE and NEG_RISK_CTF_EXCHANGE as public, users can verify the
* these private variables from outside the contract.
*
* protocolFeeRecipient, protocolFeeBasisPoints and minimumOrderFeeRate are private, but
* they can be accessed off-chain using `ethers.getStorageAt`.
*
* @param _owner Contract owner
* @param _protocolFeeRecipient Protocol fee recipient
* @param _ctfExchange predict.fun CTF exchange
* @param _negRiskCtfExchange predict.fun neg risk CTF exchange
* @param _umaCtfAdapter Binary outcome UMA CTF adapter
* @param _negRiskUmaCtfAdapter Neg risk UMA CTF adapter
*/
constructor(
address _owner,
address _protocolFeeRecipient,
address _ctfExchange,
address _negRiskCtfExchange,
address _umaCtfAdapter,
address _negRiskUmaCtfAdapter
) EIP712("predict.loan", "1") {
CTF_EXCHANGE = ICTFExchange(_ctfExchange);
NEG_RISK_CTF_EXCHANGE = ICTFExchange(_negRiskCtfExchange);
LOAN_TOKEN = IERC20(CTF_EXCHANGE.getCollateral());
if (address(LOAN_TOKEN) != NEG_RISK_CTF_EXCHANGE.getCollateral()) {
revert OnlyOneLoanTokenAllowed();
}
UMA_CTF_ADAPTER = _umaCtfAdapter;
NEG_RISK_UMA_CTF_ADAPTER = _negRiskUmaCtfAdapter;
NEG_RISK_ADAPTER = INegRiskAdapter(NEG_RISK_CTF_EXCHANGE.getCtf());
CTF = IConditionalTokens(CTF_EXCHANGE.getCtf());
if (NEG_RISK_ADAPTER.ctf() != address(CTF)) {
revert OnlyOneCTFAllowed();
}
_grantRole(DEFAULT_ADMIN_ROLE, _owner);
_updateProtocolFeeRecipient(_protocolFeeRecipient);
}
/*//////////////////////////////////////////////////////////////
KEY FLOW
//////////////////////////////////////////////////////////////*/
/**
* @inheritdoc IPredictDotLoan
*/
function acceptBorrowRequest(
Proposal calldata proposal,
uint256 fulfillAmount
) external nonReentrant whenNotPaused {
_assertProposalIsBorrowRequest(proposal);
_acceptOffer(proposal, fulfillAmount);
}
/**
* @inheritdoc IPredictDotLoan
*/
function acceptLoanOffer(Proposal calldata proposal, uint256 fulfillAmount) external nonReentrant whenNotPaused {
_assertProposalIsLoanOffer(proposal);
_acceptOffer(proposal, fulfillAmount);
}
/**
* @inheritdoc IPredictDotLoan
*/
function acceptLoanOfferAndFillOrder(
Order calldata exchangeOrder,
Proposal calldata proposal
) external nonReentrant whenNotPaused {
_assertProposalIsLoanOffer(proposal);
uint256 positionId = _derivePositionId(proposal);
if (exchangeOrder.tokenId != positionId) {
revert PositionIdMismatch();
}
if (exchangeOrder.side != Side.SELL) {
revert NotSellOrder();
}
if (exchangeOrder.feeRateBps < minimumOrderFeeRate) {
revert OrderFeeRateTooLow();
}
bytes32 proposalId = hashProposal(proposal);
uint256 protocolFee = (exchangeOrder.takerAmount * protocolFeeBasisPoints) / 10_000;
uint256 fulfillAmount = exchangeOrder.takerAmount + protocolFee;
_assertProposalValidity(proposalId, proposal, positionId, fulfillAmount);
Fulfillment storage fulfillment = _getFulfillment(proposal);
uint256 collateralAmountRequired = _calculateCollateralAmountRequired(proposal, fulfillment, fulfillAmount);
if (exchangeOrder.makerAmount < collateralAmountRequired) {
revert InsufficientCollateral();
}
_updateFulfillment(fulfillment, collateralAmountRequired, fulfillAmount, proposalId);
_transferLoanAmountAndProtocolFeeWithoutDeductingFromLoanAmount(
proposal.from,
address(this),
exchangeOrder.takerAmount,
protocolFee
);
uint256 collateralTokenBalance = _getPositionBalance(positionId);
_fillOrder(exchangeOrder, _selectExchangeForQuestionType(proposal.questionType));
{
uint256 collateralTokenBalanceIncrease = _getPositionBalance(positionId) - collateralTokenBalance;
if (collateralTokenBalanceIncrease < exchangeOrder.makerAmount) {
revert OrderDidNotFill();
}
_transferExcessCollateralIfAny(
positionId,
msg.sender,
collateralAmountRequired,
collateralTokenBalanceIncrease
);
if (exchangeOrder.feeRateBps > minimumOrderFeeRate) {
uint256 refund = CalculatorHelper.calcRefund(
exchangeOrder.feeRateBps,
minimumOrderFeeRate,
collateralTokenBalanceIncrease,
exchangeOrder.makerAmount,
exchangeOrder.takerAmount,
Side.SELL
);
LOAN_TOKEN.safeTransfer(exchangeOrder.maker, refund);
}
uint256 protocolFeesNotRefunded = LOAN_TOKEN.balanceOf(address(this));
if (protocolFeesNotRefunded > 0) {
LOAN_TOKEN.safeTransfer(protocolFeeRecipient, protocolFeesNotRefunded);
}
}
_createLoan(
nextLoanId,
proposal,
positionId,
proposal.from,
msg.sender,
collateralAmountRequired,
fulfillAmount
);
emit OrderFilledUsingProposal(
proposalId,
nextLoanId,
msg.sender,
proposal.from,
positionId,
collateralAmountRequired,
fulfillAmount,
protocolFee
);
unchecked {
++nextLoanId;
}
}
/**
* @inheritdoc IPredictDotLoan
*/
function matchProposals(
Proposal calldata borrowRequest,
Proposal calldata loanOffer
) external nonReentrant whenNotPaused {
_assertProposalIsBorrowRequest(borrowRequest);
_assertProposalIsLoanOffer(loanOffer);
_assertLenderIsNotBorrower(loanOffer.from, borrowRequest.from);
uint256 positionId = _derivePositionId(borrowRequest);
// This also indirectly checks that the questionType is the same
if (positionId != _derivePositionId(loanOffer)) {
revert PositionIdMismatch();
}
_assertPositionTradeableOnExchange(positionId, borrowRequest.questionType);
_assertValidInterestRatePerSecond(loanOffer.interestRatePerSecond);
_assertValidInterestRatePerSecond(borrowRequest.interestRatePerSecond);
if (borrowRequest.interestRatePerSecond < loanOffer.interestRatePerSecond) {
revert UnacceptableInterestRatePerSecond();
}
if (borrowRequest.duration > loanOffer.duration) {
revert UnacceptableDuration();
}
_assertCollateralizationRatioAtLeastOneHundredPercent(loanOffer.collateralAmount, loanOffer.loanAmount);
_assertCollateralizationRatioAtLeastOneHundredPercent(borrowRequest.collateralAmount, borrowRequest.loanAmount);
if (
borrowRequest.collateralAmount * loanOffer.loanAmount <
borrowRequest.loanAmount * loanOffer.collateralAmount
) {
revert UnacceptableCollateralizationRatio();
}
_assertNotExpired(borrowRequest.validUntil);
_assertNotExpired(loanOffer.validUntil);
_assertMatchingProtocolFeeBasisPoints(loanOffer.protocolFeeBasisPoints);
_assertMatchingProtocolFeeBasisPoints(borrowRequest.protocolFeeBasisPoints);
bytes32 loanOfferProposalId = hashProposal(loanOffer);
_assertValidSignature(loanOfferProposalId, loanOffer.from, loanOffer.signature);
bytes32 borrowRequestProposalId = hashProposal(borrowRequest);
_assertValidSignature(borrowRequestProposalId, borrowRequest.from, borrowRequest.signature);
// To fix stack too deep when via-IR is turned off
uint256 fulfillAmount;
uint256 collateralAmountRequired;
{
Fulfillment storage loanOfferFulfillment = _getFulfillment(loanOffer);
Fulfillment storage borrowRequestFulfillment = _getFulfillment(borrowRequest);
_assertSaltNotUsedByAnotherProposal(borrowRequestFulfillment.proposalId, borrowRequestProposalId);
_assertSaltNotUsedByAnotherProposal(loanOfferFulfillment.proposalId, loanOfferProposalId);
uint256 loanOfferFulfilledAmount = loanOfferFulfillment.loanAmount;
uint256 borrowRequestFulfilledAmount = borrowRequestFulfillment.loanAmount;
uint256 loanOfferAvailableFulfillAmount = loanOffer.loanAmount - loanOfferFulfilledAmount;
uint256 borrowRequestAvailableFulfillAmount = borrowRequest.loanAmount - borrowRequestFulfilledAmount;
// No need to check _assertFulfillAmountNotTooHigh
fulfillAmount = loanOfferAvailableFulfillAmount > borrowRequestAvailableFulfillAmount
? borrowRequestAvailableFulfillAmount
: loanOfferAvailableFulfillAmount;
_assertFulfillAmountNotTooLow(fulfillAmount, borrowRequestFulfilledAmount, borrowRequest.loanAmount);
_assertFulfillAmountNotTooLow(fulfillAmount, loanOfferFulfilledAmount, loanOffer.loanAmount);
collateralAmountRequired = _calculateCollateralAmountRequired(
loanOffer,
loanOfferFulfillment,
fulfillAmount
);
_updateFulfillment(
borrowRequestFulfillment,
collateralAmountRequired,
fulfillAmount,
borrowRequestProposalId
);
_updateFulfillment(loanOfferFulfillment, collateralAmountRequired, fulfillAmount, loanOfferProposalId);
}
_assertProposalNotCancelled(borrowRequest.from, borrowRequest.salt, borrowRequest.proposalType);
_assertProposalNotCancelled(loanOffer.from, loanOffer.salt, loanOffer.proposalType);
_assertProposalNonceIsCurrent(loanOffer.proposalType, loanOffer.from, loanOffer.nonce);
_assertProposalNonceIsCurrent(borrowRequest.proposalType, borrowRequest.from, borrowRequest.nonce);
// Just need to check borrow request's question as the question is the same
_assertQuestionPriceUnavailable(borrowRequest.questionType, borrowRequest.questionId);
uint256 protocolFee = _transferLoanAmountAndProtocolFee(loanOffer.from, borrowRequest.from, fulfillAmount);
CTF.safeTransferFrom(borrowRequest.from, address(this), positionId, collateralAmountRequired, "");
uint256 _nextLoanId = nextLoanId;
_createLoan(
_nextLoanId,
loanOffer,
positionId,
loanOffer.from,
borrowRequest.from,
collateralAmountRequired,
fulfillAmount
);
emit ProposalsMatched(
loanOfferProposalId,
borrowRequestProposalId,
_nextLoanId,
borrowRequest.from,
loanOffer.from,
positionId,
collateralAmountRequired,
fulfillAmount,
protocolFee
);
unchecked {
++nextLoanId;
}
}
/**
* @inheritdoc IPredictDotLoan
*/
function repay(uint256 loanId) external nonReentrant {
Loan storage loan = loans[loanId];
_assertAuthorizedCaller(loan.borrower);
LoanStatus status = loan.status;
if (status != LoanStatus.Active) {
if (status != LoanStatus.Called) {
revert InvalidLoanStatus();
}
}
uint256 debt = _calculateDebt(loan.loanAmount, loan.interestRatePerSecond, _calculateLoanTimeElapsed(loan));
loan.status = LoanStatus.Repaid;
LOAN_TOKEN.safeTransferFrom(msg.sender, loan.lender, debt);
CTF.safeTransferFrom(address(this), msg.sender, loan.positionId, loan.collateralAmount, "");
emit LoanRepaid(loanId, debt);
}
/**
* @inheritdoc IPredictDotLoan
*/
function refinance(Refinancing calldata refinancing) external nonReentrant whenNotPaused {
_assertAuthorizedCaller(loans[refinancing.loanId].borrower);
(uint256 id, Loan memory loan, uint256 protocolFee) = _refinance(refinancing);
emit LoanRefinanced(
hashProposal(refinancing.proposal),
refinancing.loanId,
id,
loan.lender,
loan.collateralAmount,
loan.loanAmount,
loan.interestRatePerSecond,
loan.minimumDuration,
protocolFee
);
}
/**
* @inheritdoc IPredictDotLoan
*/
function refinance(
Refinancing[] calldata refinancings
) external nonReentrant whenNotPaused onlyRole(REFINANCIER_ROLE) {
RefinancingResult[] memory results = new RefinancingResult[](refinancings.length);
for (uint256 i; i < refinancings.length; ++i) {
Refinancing calldata refinancing = refinancings[i];
(uint256 id, Loan memory loan, uint256 protocolFee) = _refinance(refinancing);
// Doing this check after the refinancing, but in realitiy
// it does not matter because the transaction simulation would've
// failed before it is submitted on-chain.
address borrower = loan.borrower;
if (autoRefinancingEnabled[borrower] == 0) {
revert BorrowerDidNotEnableAutoRefinancing(borrower);
}
results[i] = RefinancingResult(
hashProposal(refinancing.proposal),
refinancing.loanId,
id,
loan.lender,
loan.collateralAmount,
loan.loanAmount,
loan.interestRatePerSecond,
loan.minimumDuration,
protocolFee
);
}
emit LoansRefinanced(results);
}
/**
* @inheritdoc IPredictDotLoan
*/
function call(uint256 loanId) external nonReentrant {
Loan storage loan = loans[loanId];
_assertAuthorizedCaller(loan.lender);
_assertLoanStatus(loan.status, LoanStatus.Active);
if (loan.startTime + loan.minimumDuration > block.timestamp) {
revert LoanNotMatured();
}
if (_isQuestionPriceAvailable(loan.questionType, positionQuestion[loan.positionId])) {
_seize(loanId, loan);
} else {
loan.status = LoanStatus.Called;
loan.callTime = block.timestamp;
emit LoanCalled(loanId);
}
}
/**
* @inheritdoc IPredictDotLoan
*
* @dev Loans created via an auction does not have a minimum duration as the new lender is already
* taking a risk on a borrower who has a history of not repaying. The new lender is free to
* trigger an auction any time.
*/
function auction(uint256 loanId) external nonReentrant whenNotPaused {
Loan storage loan = loans[loanId];
_assertLoanStatus(loan.status, LoanStatus.Called);
_assertLenderIsNotBorrower(msg.sender, loan.borrower);
_assertNewLenderIsNotTheSameAsOldLender(msg.sender, loan.lender);
uint256 callTime = loan.callTime;
uint256 timeElapsed = block.timestamp - callTime;
_assertAuctionIsActive(timeElapsed);
// If the question is resolved in the middle of the auction, the lender can wait for the auction to be over
// and seize the collateral
_assertQuestionPriceUnavailable(loan.questionType, positionQuestion[loan.positionId]);
uint256 interestRatePerSecond = _auctionCurrentInterestRatePerSecond(timeElapsed);
loan.status = LoanStatus.Auctioned;
uint256 _nextLoanId = nextLoanId;
uint256 debt = _calculateDebt(loan.loanAmount, loan.interestRatePerSecond, callTime - loan.startTime);
uint256 protocolFee = (debt * protocolFeeBasisPoints) / 10_000;
Loan storage newLoan = loans[_nextLoanId];
newLoan.borrower = loan.borrower;
newLoan.lender = msg.sender;
newLoan.positionId = loan.positionId;
newLoan.collateralAmount = loan.collateralAmount;
newLoan.loanAmount = debt + protocolFee;
newLoan.interestRatePerSecond = interestRatePerSecond;
newLoan.startTime = block.timestamp;
newLoan.status = LoanStatus.Active;
newLoan.questionType = loan.questionType;
_transferLoanAmountAndProtocolFeeWithoutDeductingFromLoanAmount(msg.sender, loan.lender, debt, protocolFee);
unchecked {
++nextLoanId;
}
emit LoanTransferred(loanId, debt, protocolFee, _nextLoanId, msg.sender, interestRatePerSecond);
}
/**
* @inheritdoc IPredictDotLoan
*/
function seize(uint256 loanId) external nonReentrant {
Loan storage loan = loans[loanId];
_assertAuthorizedCaller(loan.lender);
_assertLoanStatus(loan.status, LoanStatus.Called);
if (!_isQuestionPriceAvailable(loan.questionType, positionQuestion[loan.positionId])) {
if (loan.callTime + AUCTION_DURATION >= block.timestamp) {
revert AuctionNotOver();
}
}
_seize(loanId, loan);
}
/*//////////////////////////////////////////////////////////////
CANCELLATION FUNCTIONS
//////////////////////////////////////////////////////////////*/
/**
* @inheritdoc IPredictDotLoan
*/
function cancel(SaltCancellationRequest[] calldata requests) external {
if (requests.length == 0) {
revert NoSaltCancellationRequests();
}
for (uint256 i; i < requests.length; ++i) {
SaltCancellationRequest calldata request = requests[i];
uint256 salt = request.salt;
SaltCancellationStatus storage status = saltCancellations[msg.sender][salt];
if (!request.lending && !request.borrowing) {
revert NotCancelling();
}
if (request.lending) {
if (status.lending) {
revert SaltAlreadyCancelled(salt);
}
status.lending = true;
}
if (request.borrowing) {
if (status.borrowing) {
revert SaltAlreadyCancelled(salt);
}
status.borrowing = true;
}
}
emit SaltsCancelled(msg.sender, requests);
}
/**
* @inheritdoc IPredictDotLoan
*/
function incrementNonces(bool lending, bool borrowing) external {
if (!lending && !borrowing) {
revert NotIncrementing();
}
uint128 lendingNonce = nonces[msg.sender].lending;
uint128 borrowingNonce = nonces[msg.sender].borrowing;
if (lending) {
unchecked {
nonces[msg.sender].lending = ++lendingNonce;
}
}
if (borrowing) {
unchecked {
nonces[msg.sender].borrowing = ++borrowingNonce;
}
}
emit NoncesIncremented(lendingNonce, borrowingNonce);
}
/**
* @inheritdoc IPredictDotLoan
*/
function toggleAutoRefinancingEnabled() external {
uint256 preference = autoRefinancingEnabled[msg.sender] == 0 ? 1 : 0;
autoRefinancingEnabled[msg.sender] = preference;
emit AutoRefinancingEnabledToggled(msg.sender, preference);
}
/*//////////////////////////////////////////////////////////////
ADMIN-ONLY FUNCTIONS
//////////////////////////////////////////////////////////////*/
/**
* @notice Update the minimum order fee rate. Only callable by admins.
*
* @dev predict.fun's max fee rate is 10% but we are not going to check it here.
* We can disable acceptLoanOfferAndFillOrder if needed by setting minimumOrderFeeRate
* to a value higher than 10%.
*
* @param _minimumOrderFeeRate The minimum order fee rate
*/
function updateMinimumOrderFeeRate(uint16 _minimumOrderFeeRate) external onlyRole(DEFAULT_ADMIN_ROLE) {
minimumOrderFeeRate = _minimumOrderFeeRate;
emit MinimumOrderFeeRateUpdated(_minimumOrderFeeRate);
}
/**
* @notice Update the protocol fee basis points. Only callable by admins.
*
* @param _protocolFeeBasisPoints The protocol fee basis points
*/
function updateProtocolFeeBasisPoints(uint8 _protocolFeeBasisPoints) external onlyRole(DEFAULT_ADMIN_ROLE) {
if (_protocolFeeBasisPoints > MAXIMUM_PROTOCOL_FEE_BASIS_POINTS) {
revert ProtocolFeeBasisPointsTooHigh();
}
protocolFeeBasisPoints = _protocolFeeBasisPoints;
emit ProtocolFeeBasisPointsUpdated(_protocolFeeBasisPoints);
}
/**
* @notice When a contract is paused, no new loans including refinancing and auction can be created.
* All operations with existing loans still work.
* Only callable by admins.
*/
function togglePaused() external onlyRole(DEFAULT_ADMIN_ROLE) {
paused() ? _unpause() : _pause();
}
/**
* @notice Update the protocol fee recipient. Only callable by admins.
*
* @param _protocolFeeRecipient The address of the protocol fee recipient
*/
function updateProtocolFeeRecipient(address _protocolFeeRecipient) external onlyRole(DEFAULT_ADMIN_ROLE) {
_updateProtocolFeeRecipient(_protocolFeeRecipient);
}
/*//////////////////////////////////////////////////////////////
VIEW-ONLY FUNCTIONS
//////////////////////////////////////////////////////////////*/
/**
* @inheritdoc IPredictDotLoan
*/
function auctionCurrentInterestRatePerSecond(
uint256 loanId
) external view returns (uint256 currentInterestRatePerSecond) {
Loan storage loan = loans[loanId];
_assertLoanStatus(loan.status, LoanStatus.Called);
uint256 timeElapsed = block.timestamp - loan.callTime;
_assertAuctionIsActive(timeElapsed);
currentInterestRatePerSecond = _auctionCurrentInterestRatePerSecond(timeElapsed);
}
/**
* @inheritdoc IPredictDotLoan
*/
function calculateDebt(uint256 loanId) external view returns (uint256 debt) {
Loan storage loan = loans[loanId];
if (loan.status != LoanStatus.Active) {
if (loan.status != LoanStatus.Called) {
return 0;
}
}
debt = _calculateDebt(loan.loanAmount, loan.interestRatePerSecond, _calculateLoanTimeElapsed(loan));
}
/**
* @inheritdoc IPredictDotLoan
*/
function calculateCollateralAmountRequired(
Proposal calldata proposal,
uint256 fulfillAmount
) public view returns (uint256 collateralAmountRequired) {
Fulfillment storage fulfillment = _getFulfillment(proposal);
_assertFulfillAmountNotTooLow(fulfillAmount, fulfillment.loanAmount, proposal.loanAmount);
_assertFulfillAmountNotTooHigh(fulfillAmount, fulfillment.loanAmount, proposal.loanAmount);
collateralAmountRequired = _calculateCollateralAmountRequired(proposal, fulfillment, fulfillAmount);
}
/**
* @inheritdoc IPredictDotLoan
*/
function getFulfillment(
Proposal calldata proposal
) external view returns (bytes32 proposalId, uint256 collateralAmount, uint256 loanAmount) {
Fulfillment storage fulfillment = _getFulfillment(proposal);
proposalId = fulfillment.proposalId;
collateralAmount = fulfillment.collateralAmount;
loanAmount = fulfillment.loanAmount;
}
/**
* @inheritdoc IPredictDotLoan
*/
function hashProposal(Proposal calldata proposal) public view returns (bytes32 digest) {
digest = _hashTypedDataV4(
keccak256(
abi.encode(
keccak256(
"Proposal(address from,uint256 loanAmount,uint256 collateralAmount,uint8 questionType,uint256 questionId,bool outcome,uint256 interestRatePerSecond,uint256 duration,uint256 validUntil,uint256 salt,uint256 nonce,uint8 proposalType,uint256 protocolFeeBasisPoints)"
),
proposal.from,
proposal.loanAmount,
proposal.collateralAmount,
proposal.questionType,
proposal.questionId,
proposal.outcome,
proposal.interestRatePerSecond,
proposal.duration,
proposal.validUntil,
proposal.salt,
proposal.nonce,
proposal.proposalType,
proposal.protocolFeeBasisPoints
)
)
);
}
/**
* @notice Query if a contract implements an interface
*
* @param interfaceId The interface identifier, as specified in ERC-165
*
* @return `true` if the contract implements `interfaceId` and `interfaceId` is not 0xffffffff, `false` otherwise
*/
function supportsInterface(bytes4 interfaceId) public view override(AccessControl, ERC1155Holder) returns (bool) {
return
interfaceId == type(AccessControl).interfaceId ||
interfaceId == type(ERC1155Holder).interfaceId ||
super.supportsInterface(interfaceId);
}
function onERC1155Received(
address,
address,
uint256,
uint256,
bytes memory
) public virtual override returns (bytes4) {
_assertTokenReceivedIsCTF();
return this.onERC1155Received.selector;
}
function onERC1155BatchReceived(
address,
address,
uint256[] memory,
uint256[] memory,
bytes memory
) public virtual override returns (bytes4) {
_assertTokenReceivedIsCTF();
return this.onERC1155BatchReceived.selector;
}
/*//////////////////////////////////////////////////////////////
LOAN TOKEN TRANSFER LOGIC
//////////////////////////////////////////////////////////////*/
function _seize(uint256 loanId, Loan storage loan) private {
loan.status = LoanStatus.Defaulted;
CTF.safeTransferFrom(address(this), msg.sender, loan.positionId, loan.collateralAmount, "");
emit LoanDefaulted(loanId);
}
/**
* @dev Transfer loan amount from one address to another.
* If the protocol fee is greater than 0, deduct the protocol fee from the loan amount.
*/
function _transferLoanAmountAndProtocolFee(
address from,
address to,
uint256 loanAmount
) private returns (uint256 protocolFee) {
protocolFee = (loanAmount * protocolFeeBasisPoints) / 10_000;
LOAN_TOKEN.safeTransferFrom(from, to, loanAmount - protocolFee);
if (protocolFee > 0) {
LOAN_TOKEN.safeTransferFrom(from, protocolFeeRecipient, protocolFee);
}
}
/**
* @dev Transfer loan amount from one address to another.
* If the protocol fee is greater than 0, do not deduct the protocol fee from the loan amount.
* The protocol fee is on top of the loan amount.
*/
function _transferLoanAmountAndProtocolFeeWithoutDeductingFromLoanAmount(
address from,
address to,
uint256 loanAmount,
uint256 protocolFee
) private {
LOAN_TOKEN.safeTransferFrom(from, to, loanAmount);
if (protocolFee > 0) {
LOAN_TOKEN.safeTransferFrom(from, protocolFeeRecipient, protocolFee);
}
}
function _transferExcessCollateralIfAny(
uint256 positionId,
address receiver,
uint256 collateralAmountRequired,
uint256 actualCollateralAmount
) private {
uint256 excessCollateral = actualCollateralAmount - collateralAmountRequired;
if (excessCollateral > 0) {
CTF.safeTransferFrom(address(this), receiver, positionId, excessCollateral, "");
}
}
/*//////////////////////////////////////////////////////////////
EXCHANGE ORDER FULFILLMENT LOGIC
//////////////////////////////////////////////////////////////*/
function _fillOrder(Order calldata exchangeOrder, ICTFExchange exchange) private {
LOAN_TOKEN.safeIncreaseAllowance(address(exchange), exchangeOrder.takerAmount);
exchange.fillOrder(exchangeOrder, exchangeOrder.makerAmount);
LOAN_TOKEN.forceApprove(address(exchange), 0);
}
function _selectExchangeForQuestionType(QuestionType questionType) private view returns (ICTFExchange exchange) {
exchange = questionType == QuestionType.Binary ? CTF_EXCHANGE : NEG_RISK_CTF_EXCHANGE;
}
/*//////////////////////////////////////////////////////////////
FULFILLMENT LOGIC
//////////////////////////////////////////////////////////////*/
/**
* @dev The unique key is created by hashing a user's address, salt, and proposal type.
*/
function _getFulfillment(Proposal calldata proposal) private view returns (Fulfillment storage fulfillment) {
fulfillment = fulfillments[keccak256(abi.encodePacked(proposal.from, proposal.salt, proposal.proposalType))];
}
/**
* @dev Keep track of a proposal's collateral taken and loan amount given out so far.
*/
function _updateFulfillment(
Fulfillment storage fulfillment,
uint256 collateralAmountRequired,
uint256 fulfillAmount,
bytes32 proposalId
) private {
fulfillment.collateralAmount += collateralAmountRequired;
fulfillment.loanAmount += fulfillAmount;
if (fulfillment.proposalId == bytes32(0)) {
fulfillment.proposalId = proposalId;
}
}
/*//////////////////////////////////////////////////////////////
CREATE LOAN LOGIC
//////////////////////////////////////////////////////////////*/
function _acceptOffer(Proposal calldata proposal, uint256 fulfillAmount) private {
bytes32 proposalId = hashProposal(proposal);
uint256 positionId = _derivePositionId(proposal);
_assertProposalValidity(proposalId, proposal, positionId, fulfillAmount);
Fulfillment storage fulfillment = _getFulfillment(proposal);
uint256 collateralAmountRequired = _calculateCollateralAmountRequired(proposal, fulfillment, fulfillAmount);
_updateFulfillment(fulfillment, collateralAmountRequired, fulfillAmount, proposalId);
address lender = proposal.proposalType == ProposalType.LoanOffer ? proposal.from : msg.sender;
address borrower = lender == msg.sender ? proposal.from : msg.sender;
uint256 protocolFee = _transferLoanAmountAndProtocolFee(lender, borrower, fulfillAmount);
CTF.safeTransferFrom(borrower, address(this), positionId, collateralAmountRequired, "");
_createLoan(nextLoanId, proposal, positionId, lender, borrower, collateralAmountRequired, fulfillAmount);
emit ProposalAccepted(
nextLoanId,
proposalId,
borrower,
lender,
positionId,