build.gradle

plugins {
    id 'java'
    id 'maven-publish'
    id 'com.diffplug.spotless' version '6.25.0'
    id 'org.sonarqube' version '5.1.0.4882'
    id 'jacoco'
}

repositories {
    mavenLocal()
    mavenCentral()
}

dependencies {
    testImplementation 'org.junit.jupiter:junit-jupiter:[5.11.0,)'
    testImplementation 'org.hamcrest:hamcrest-core:[2.2,)'
    testImplementation 'org.zapodot:embedded-db-junit-jupiter:[2.2.0,)'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher:[1.11.0,)'
}

test {
    useJUnitPlatform()
    maxParallelForks = Runtime.runtime.availableProcessors()
}

group = 'com.github.javadev'
version = '1.37-SNAPSHOT'
description = 'leetcode-in-java'
java.sourceCompatibility = JavaVersion.VERSION_17

java {
    withSourcesJar()
    withJavadocJar()
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'
}

spotless {
    java {
        encoding 'UTF-8'
        target fileTree(projectDir) {
            include '**/src/**/*.java'
            exclude '**/build/**'
        }
        importOrder '\\#', '', '*'
        removeUnusedImports()
        googleJavaFormat('1.22.0').aosp()
        toggleOffOn()
        endWithNewline()
    }
}

jacocoTestReport {
    reports {
        xml.required = true
        html.required = false
    }
}