libdynd-config.bat.in

@echo off

if NOT "%1"=="-libnames" goto notlibnames
    echo @DYND_LIB_FILE@;@DYNDT_LIB_FILE@
    exit /B 0
:notlibnames

if NOT "%1"=="-libdyndname" goto notlibdyndname
    echo @DYND_LIB_FILE@
    exit /B 0
:notlibdyndname

if NOT "%1"=="-libdyndtname" goto notlibdyndtname
    echo @DYNDT_LIB_FILE@
    exit /B 0
:notlibdyndtname

if NOT "%1"=="-libdir" goto notlibdir
    REM This batch file should be in a ...\bin relative to ...\lib
    pushd %~f0\..\..\lib
    echo %CD%
    popd
    exit /B 0
:notlibdir

if NOT "%1"=="-includedir" goto notincludedir
    REM This batch file should be in a ...\bin relative to ...\include
    pushd %~f0\..\..\include
    echo %CD%
    popd
    exit /B 0
:notincludedir

if NOT "%1"=="-rootdir" goto notrootdir
    REM This batch file should be in a ...\bin relative to ...\include
    pushd %~f0\..\..
    echo %CD%
    popd
    exit /B 0
:notrootdir

if NOT "%1"=="-version" goto notversion
    echo @DYND_VERSION_STRING@
    exit /B 0
:notversion

echo Usage: %0 OPTION
echo Print information for linking libdynd.
echo
echo Options:
echo   -libnames      Prints a semicolon separated list of the library names.
echo   -libdyndname   Prints the name of the dynd library.
echo   -libdyndtname  Prints the name of the dyndt library.
echo   -libdir        Prints the full path of the directory containing the libraries.
echo   -includedir    Prints the directory with the libdynd include files.
echo   -version       Prints the version of libdynd.
exit /B 1