build.gradle

buildscript {
    repositories {
        jcenter()
    }
}

plugins {
    id "org.jetbrains.intellij" version "0.4.15"
}

sourceCompatibility = 1.8
targetCompatibility = 1.8

apply plugin: 'idea'
apply plugin: 'org.jetbrains.intellij'
apply plugin: 'java'

intellij {
    version 'IU-2019.3.3'
    plugins 'gradle', 'maven', 'Groovy', 'properties', 'java', 'org.jetbrains.plugins.go:193.5662.53.103'
    pluginName 'JFrog'
    updateSinceUntilBuild = false
}

repositories {
    mavenLocal()
    maven {
        url "https://oss.jfrog.org/artifactory/libs-snapshot"
        mavenContent {
            snapshotsOnly()
        }
    }
    maven {
        url "http://oss.jfrog.org/artifactory/libs-release"
    }
}

dependencies {
    implementation group: 'com.jfrog.ide', name: 'ide-plugins-common', version: '1.2.x-SNAPSHOT'
    compile group: 'org.apache.commons', name: 'commons-lang3', version: '3.9'
}

test {
    testLogging {
        exceptionFormat "full"
        events "started", "passed", "skipped", "failed", "standardOut", "standardError"
        minGranularity 0
    }
    if (project.hasProperty('excludeTests')) {
        exclude project.property('excludeTests')
    }
}

jar {
    manifest {
        attributes 'Implementation-Version': currentVersion
    }
}

group 'com.jfrog.ide'
version currentVersion // Plugin version