QML WPEView dynamic loading

[gregor26]

Hi,

I'm evaluating WPEQt a bit and have an issue with WPEView control. When using WPEView component in root QML file, all works as expected. But in case QML component which includes WPEView is dynamically created, WPEView is not loaded and nothing is shown.

Example 1 - WPEView is used in the root QML file, all is ok.

/// main.qml ///
import QtQuick 2.15
import QtQuick.Window 2.15
import QtQuick.Controls 2.15
import org.wpewebkit.qtwpe 1.0

Window {
    width: 640
    height: 480
    title: qsTr("WPEQt Demo")
    visible: true

    Rectangle {
        id: rect1
        anchors.top: button1.bottom
        anchors.right: parent.right
        anchors.left: parent.left
        anchors.bottom: parent.bottom
        color: "grey"

        Rectangle {
            x: 10
            y: 10
            width: 620
            height: 410

            color:"lightblue"

            WPEView {
                anchors.fill: parent
                url: "https://www.google.com/"
            }
        }
    }
}

Example 2 - loaded dynamically (WPEView is part of MyRect which is loaded on button press), WPEView is not loaded/shown.

/// main.qml ///
import QtQuick 2.15
import QtQuick.Window 2.15
import QtQuick.Controls 2.15

Window {
    width: 640
    height: 480
    title: qsTr("WPEQt Demo")
    visible: true

    property var myrect

    Button {
        id: button1
        text: qsTr("Button 1")
        width: parent.width / 2
        height: 0.1 * parent.height
        anchors.top: parent.top
        anchors.left: parent.left
        onClicked: {
            console.log("button1 clicked")

            var component = Qt.createComponent("MyRect.qml");
            myrect = component.createObject(rect1);
        }
    }

    Button {
        id: button2
        text: qsTr("Button 2")
        width: parent.width / 2
        height: 0.1 * parent.height
        anchors.top: parent.top
        anchors.right: parent.right
        onClicked: {
            console.log("button2 clicked")

            myrect.destroy(10);
        }
    }

    Rectangle {
        id: rect1
        anchors.top: button1.bottom
        anchors.right: parent.right
        anchors.left: parent.left
        anchors.bottom: parent.bottom
        color: "grey"
    }
}


/// MyRect.qml ///
import QtQuick 2.15
import org.wpewebkit.qtwpe 1.0

Item {
    id: myrectitem

    Rectangle {
        x: 10
        y: 10
        width: 620
        height: 410

        color:"lightblue"

        WPEView {
            anchors.fill: parent
            url: "https://www.google.com/"
        }
    }
}

Appreciate any answers or ideas on how to continue. Thanks.

Gregor

[philn]

Can you check if this method returns too early? https://github.com/WebKit/WebKit/blob/main/Source/WebKit/UIProcess/API/wpe/qt/WPEQtView.cpp#L175

[gregor26]

Thanks for the answer. Don't have a means at the moment to check/verify this.

Did a small further check and tried to update the url, change enable/visible status on some delay after dynamic control gets loaded and results for the wpeview are the same .. nothing visible and no status/loading changes.

[philn]

I don't have time to check this either. Let us know if you manage to investigate this! If I find the time to do it I'll comment as well.

[gregor26]

Managed to add some console outputs to WPEQtView.cpp method WPEQtView::updatePaintNode.

QSGNode* WPEQtView::updatePaintNode(QSGNode* node, UpdatePaintNodeData*)
{ 
   qDebug() << "WPEQtView::updatePaintNode - 1";     

   if (!m_webView || !m_backend)        
      return node;

   qDebug() << "WPEQtView::updatePaintNode - 2";

   auto* textureNode = static_cast<QSGSimpleTextureNode*>(node);    
   if (!textureNode)        
      textureNode = new QSGSimpleTextureNode();  

   qDebug() << "WPEQtView::updatePaintNode - 3";

   GLuint textureId = m_backend->texture(window()->openglContext());    
   if (!textureId)        
      return node;

#if (QT_VERSION >= QT_VERSION_CHECK(5, 15, 0))    
   qDebug() << "WPEQtView::updatePaintNode - 4";  

   auto texture = window()->createTextureFromNativeObject(QQuickWindow::NativeObjectTexture, &textureId, 0, m_size.toSize(), QQuickWindow::TextureHasAlphaChannel);
#else 
   qDebug() << "WPEQtView::updatePaintNode - 5";

   auto texture = window()->createTextureFromId(textureId, m_size.toSize(), QQuickWindow::TextureHasAlphaChannel);
#endif    
   textureNode->setTexture(texture);    
   textureNode->setRect(boundingRect());  

   qDebug() << "WPEQtView::updatePaintNode - 6";     
   return textureNode;
}

Using this on root qml, results are as follows:

WPEQtView::updatePaintNode - 1
qml: QML root - window component loaded
WPEQtView::updatePaintNode - 1
WPEQtView::updatePaintNode - 2
WPEQtView::updatePaintNode - 3
WPEQtView::updatePaintNode - 4
WPEQtView::updatePaintNode - 6
WPEQtView::updatePaintNode - 1
WPEQtView::updatePaintNode - 2
WPEQtView::updatePaintNode - 3
WPEQtView::updatePaintNode - 4
WPEQtView::updatePaintNode - 6
.. and continuing/repeating

While results on dynamic loading are next:

qml: QML root - window component loaded
qml: QML root - button1 (create component) clicked
qml: QML dynam - myrectitem component loaded
qml: QML dynam - myrect component loaded
qml: QML dynam - webview component loaded
WPEQtView::updatePaintNode - 1

Method is called when all controls on dynamic class are loaded and not getting beyond 1.

[philn]

Ah, interesting, so I guess that means the webView is not created at all. Can you check if WPEQtView::configureWindow() is called? Maybe the sceneGraphInitialized signal is not fired?

[gregor26]

Added some more ouputs (methods geometryChanged, configureWindow, createWebView) and results are as follows:

qml: QML - window component loaded
qml: QML - button1 (create component) clicked
WPEQtView::configureWindow - 1
WPEQtView::configureWindow - 2
WPEQtView::configureWindow - 3
WPEQtView::geometryChanged - 1
WPEQtView::geometryChanged - 2
qml: QML - myrectitem component loaded
qml: QML - myrect component loaded
qml: QML - webview component loaded
WPEQtView::updatePaintNode - 1

Method configureWindow gets trough, but createWebView is never called. As it looks, signal is not emitted during dynamic load. Should there be another signal for this case?

[philn]

Maybe this signal could be used and the webview created at that moment? https://doc.qt.io/qt-5/qquickwindow.html#beforeRendering

I'm not sure, that would require more investigation.

[bith3ad]

Hi all,

I've followed the discussion here and checked the QT code base.

@gregor26 can you try to fix the line

connect(win, &QQuickWindow::sceneGraphInitialized, this, &WPEQtView::createWebView);

to

connect(win, &QQuickWindow::sceneGraphInitialized, this, &WPEQtView::createWebView, Qt::DirectConnection);

according the doc from https://github.com/qt/qtdeclarative/blob/5.15.2/src/quick/items/qquickwindow.cpp#L1590

@philn why did we not use the componentComplete (https://doc.qt.io/qt-5/qquickitem.html#componentComplete) function instead of using the signal/slot. @gregor26 could you test if componentComplete() is sufficient too?

Regrads,
Marco

[philn]

I don't remember why I used this signal specifically. If you can find a better approach that works in more situations, feel free to send a patch to WebKit's bugzilla :)

[bith3ad]

So I have a version which fixes that behavior, but I do need to verify if it is correct. I will open a bugzilla bug and link it here, so we can close this discussion.

[philn]

https://bugs.webkit.org/show_bug.cgi?id=224814