-
Notifications
You must be signed in to change notification settings - Fork 21
/
wd_core.au3
1985 lines (1729 loc) · 82.9 KB
/
wd_core.au3
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
#include-once
; standard UDF's
#include <MsgBoxConstants.au3> ; used in __WD_Error
#include <WinAPIFiles.au3> ; used in _WD_Startup
#include <WinAPIProc.au3> ; used in __WD_CloseDriver
; WebDriver related UDF's
#include "JSON.au3" ; https://www.autoitscript.com/forum/topic/148114-a-non-strict-json-udf-jsmn
#include "WinHttp.au3" ; https://www.autoitscript.com/forum/topic/84133-winhttp-functions/
#Region Copyright
#cs
* WD_Core.au3
*
* MIT License
*
* Copyright (c) 2023 Dan Pollak (@Danp2)
*
* Permission is hereby granted, free of charge, to any person obtaining a copy
* of this software and associated documentation files (the "Software"), to deal
* in the Software without restriction, including without limitation the rights
* to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
* copies of the Software, and to permit persons to whom the Software is
* furnished to do so, subject to the following conditions:
*
* The above copyright notice and this permission notice shall be included in all
* copies or substantial portions of the Software.
*
* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
* IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
* FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
* AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
* LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
* OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
* SOFTWARE.
#ce
#EndRegion Copyright
#ignorefunc _WD_IsLatestRelease
#Tidy_Parameters=/tcb=-1
#Region Description
; ==============================================================================
; UDF ...........: WD_Core.au3
; Description ...: A UDF for Web Driver automation
; Requirement ...: JSON UDF
; https://www.autoitscript.com/forum/topic/148114-a-non-strict-json-udf-jsmn
; WinHTTP UDF
; https://www.autoitscript.com/forum/topic/84133-winhttp-functions/
;
; WebDriver for desired browser
; Chrome WebDriver https://sites.google.com/chromium.org/driver/
; FireFox WebDriver https://github.com/mozilla/geckodriver/releases
; Edge WebDriver https://developer.microsoft.com/en-us/microsoft-edge/tools/webdriver/
;
; Discussion Thread on Autoit Forums
; https://www.autoitscript.com/forum/topic/191990-webdriver-udf-w3c-compliant-version
;
; Author(s) .....: Dan Pollak
; AutoIt Version : v3.3.14.5
; ==============================================================================
#EndRegion Description
#Region Many thanks to:
#cs
- Jonathan Bennett (@Jon) and the AutoIt Team
- Thorsten Willert (@Stilgar), author of FF.au3, which I've used as a model
- Michał Lipok (@mLipok) for all his feedback / suggestions
- @water for his work on the help file
#ce
#EndRegion Many thanks to:
#Region Global Constants
Global Const $__WDVERSION = "1.4.0"
Global Const $_WD_ELEMENT_ID = "element-6066-11e4-a52e-4f735466cecf"
Global Const $_WD_SHADOW_ID = "shadow-6066-11e4-a52e-4f735466cecf"
Global Const $_WD_EmptyDict = "{}"
Global Const $_WD_EmptyCaps = '{"capabilities":{}}'
Global Const $_WD_LOCATOR_ByCSSSelector = "css selector"
Global Const $_WD_LOCATOR_ByXPath = "xpath"
Global Const $_WD_LOCATOR_ByLinkText = "link text"
Global Const $_WD_LOCATOR_ByPartialLinkText = "partial link text"
Global Const $_WD_LOCATOR_ByTagName = "tag name"
Global Const $_WD_JSON_Value = "[value]"
Global Const $_WD_JSON_Element = "[value][" & $_WD_ELEMENT_ID & "]"
Global Const $_WD_JSON_Shadow = "[value][" & $_WD_SHADOW_ID & "]"
Global Const $_WD_JSON_Error = "[value][error]"
Global Const $_WD_JSON_Message = "[value][message]"
#Tidy_ILC_Pos=32
Global Enum _
$_WD_DEBUG_None = 0, _ ; No logging
$_WD_DEBUG_Error, _ ; logging in case of Error
$_WD_DEBUG_Info, _ ; logging with additional information
$_WD_DEBUG_Full ; logging with full details for developers
#Tidy_ILC_Pos=42
Global Enum _
$_WD_ERROR_Success = 0, _ ; No error
$_WD_ERROR_GeneralError, _ ; General error
$_WD_ERROR_SocketError, _ ; No socket
$_WD_ERROR_InvalidDataType, _ ; Invalid data type (IP, URL, Port ...)
$_WD_ERROR_InvalidValue, _ ; Invalid value in function-call
$_WD_ERROR_InvalidArgue, _ ; Invalid argument in function-call
$_WD_ERROR_SendRecv, _ ; Send / Recv Error
$_WD_ERROR_Timeout, _ ; Connection / Send / Recv timeout
$_WD_ERROR_NoMatch, _ ; No match for _WDAction-find/search _WDGetElement...
$_WD_ERROR_RetValue, _ ; Error echo from Repl e.g. _WDAction("fullscreen","true") <> "true"
$_WD_ERROR_Exception, _ ; Exception from web driver
$_WD_ERROR_InvalidExpression, _ ; Invalid expression in XPath query, CSSSelector query or RegEx
$_WD_ERROR_NoAlert, _ ; No alert present when calling _WD_Alert
$_WD_ERROR_NotFound, _ ; File or registry key not found
$_WD_ERROR_ElementIssue, _ ; Problem interacting with element (click intercepted, etc)
$_WD_ERROR_SessionNotCreated, _ ; Session not created
$_WD_ERROR_SessionInvalid, _ ; Invalid session ID was submitted to webdriver
$_WD_ERROR_ContextInvalid, _ ; Invalid browsing context
$_WD_ERROR_UnknownCommand, _ ; Unknown command submitted to webdriver
$_WD_ERROR_UserAbort, _ ; In case when user abort when @error occurs and $_WD_ERROR_MSGBOX was set
$_WD_ERROR_FileIssue, _ ; Errors related to WebDriver EXE File
$_WD_ERROR_NotSupported, _ ; When user try to use unsupported browser or capability
$_WD_ERROR_AlreadyDefined, _ ; Capability previously defined
$_WD_ERROR_Javascript, _ ; Javascript error
$_WD_ERROR_Mismatch, _ ; Version mismatch
$_WD_ERROR__COUNTER ; Defines row count for $aWD_ERROR_DESC
#Tidy_ILC_Pos=0
Global Const $aWD_ERROR_DESC[$_WD_ERROR__COUNTER] = [ _
"Success", _
"General Error", _
"Socket Error", _
"Invalid data type", _
"Invalid value", _
"Invalid argument", _
"Send / Recv error", _
"Timeout", _
"No match", _
"Error return value", _
"Webdriver Exception", _
"Invalid Expression", _
"No alert present", _
"Not found", _
"Element interaction issue", _
"Session not created", _
"Invalid session ID", _
"Invalid Browsing Context", _
"Unknown Command", _
"User Aborted", _
"File issue", _
"Browser or feature not supported", _
"Capability or value already defined", _
"Javascript Exception", _
"Version mismatch" _
]
Global Const $_WD_ErrorInvalidSession = "invalid session id"
Global Const $_WD_ErrorUnknownCommand = "unknown command"
Global Const $_WD_ErrorTimeout = "timeout"
Global Const $_WD_ErrorJavascript = "javascript error"
Global Const $_WD_ErrorNoSuchAlert = "no such alert"
Global Const $_WD_ErrorInvalidSelector = "invalid selector"
Global Const $_WD_ErrorElementNotFound = "no such element"
Global Const $_WD_ErrorShadowRootNotFound = "no such shadow root"
Global Const $_WD_ErrorElementStale = "stale element reference"
Global Const $_WD_ErrorElementInvalid = "invalid argument"
Global Const $_WD_ErrorElementIntercept = "element click intercepted"
Global Const $_WD_ErrorElementNotInteract = "element not interactable"
Global Const $_WD_ErrorWindowNotFound = "no such window"
Global Const $_WD_ErrorFrameNotFound = "no such frame"
Global Const $_WD_ErrorSessionNotCreated = "session not created"
Global Const $_WD_WinHTTPTimeoutMsg = "WinHTTP request timed out before Webdriver"
Global Enum _ ; Column positions of $_WD_SupportedBrowsers
$_WD_BROWSER_Name, _
$_WD_BROWSER_ExeName, _
$_WD_BROWSER_DriverName, _
$_WD_BROWSER_64Bit, _
$_WD_BROWSER_OptionsKey, _
$_WD_BROWSER_LatestReleaseURL, _
$_WD_BROWSER_LatestReleaseRegex, _
$_WD_BROWSER_NewDriverURL, _
$_WD_BROWSER__COUNTER
#Tidy_Off
Global Const $_WD_SupportedBrowsers[][$_WD_BROWSER__COUNTER] = _
[ _
[ _
"chrome", _
"chrome.exe", _
"chromedriver.exe", _
True, _
"goog:chromeOptions", _
"https://googlechromelabs.github.io/chrome-for-testing/latest-versions-per-milestone-with-downloads.json", _
'{"milestone":"%s","version":"(\d+.\d+.\d+.\d+)"', _
'"https://storage.googleapis.com/chrome-for-testing-public/" & $sDriverLatest & (($bFlag64) ? "/win64/chromedriver-win64.zip" : "/win32/chromedriver-win32.zip")' _
], _
[ _
"chrome_legacy", _ ; Prior to v115
"chrome.exe", _
"chromedriver.exe", _
False, _
"goog:chromeOptions", _
"'https://chromedriver.storage.googleapis.com/LATEST_RELEASE_' & StringLeft($sBrowserVersion, StringInStr($sBrowserVersion, '.') - 1)", _
"", _
'"https://chromedriver.storage.googleapis.com/" & $sDriverLatest & "/chromedriver_win32.zip"' _
], _
[ _
"firefox", _
"firefox.exe", _
"geckodriver.exe", _
True, _
"moz:firefoxOptions", _
"https://github.com/mozilla/geckodriver/releases/latest", _
'<a.*href="\/mozilla\/geckodriver\/releases\/tag\/(?:v)(.*?)"', _
'"https://github.com/mozilla/geckodriver/releases/download/v" & $sDriverLatest & "/geckodriver-v" & $sDriverLatest & (($bFlag64) ? "-win64.zip" : "-win32.zip")' _
], _
[ _
"msedge", _
"msedge.exe", _
"msedgedriver.exe", _
True, _
"ms:edgeOptions", _
"'https://msedgedriver.azureedge.net/LATEST_RELEASE_' & StringLeft($sBrowserVersion, StringInStr($sBrowserVersion, '.') - 1) & '_WINDOWS'", _
"", _
'"https://msedgedriver.azureedge.net/" & $sDriverLatest & "/edgedriver_" & (($bFlag64) ? "win64.zip" : "win32.zip")' _
], _
[ _
"opera", _
"opera.exe", _
"operadriver.exe", _
True, _
"goog:chromeOptions", _
"https://github.com/operasoftware/operachromiumdriver/releases/latest", _
'<a.*href="\/operasoftware\/operachromiumdriver\/releases\/tag\/(?:v\.)(.*?)"', _
'"https://github.com/operasoftware/operachromiumdriver/releases/download/v." & $sDriverLatest & "/operadriver_" & (($bFlag64) ? "win64.zip" : "win32.zip")' _
], _
[ _
"msedgeie", _
"msedge.exe", _
"IEDriverServer.exe", _
True, _
"se:ieOptions", _
"https://github.com/SeleniumHQ/selenium/blob/trunk/cpp/iedriverserver/CHANGELOG", _
'(?s)(?:major.minor.build.revision.*?v)(\d+\.\d+\.\d+)', _
'"https://github.com/SeleniumHQ/selenium/releases/download/selenium-" & StringRegExpReplace($sDriverLatest, "(\d+\.\d+)(\.\d+)", "$1") & ".0/IEDriverServer_" & (($bFlag64) ? "x64" : "Win32") & "_" & $sDriverLatest & ".zip"' _
] _
]
#Tidy_On
#EndRegion Global Constants
#Region Global Variables
#Tidy_ILC_Pos=44
Global $_WD_DRIVER = "" ; Path to web driver executable
Global $_WD_DRIVER_PARAMS = "" ; Parameters to pass to web driver executable
Global $_WD_BASE_URL = "HTTP://127.0.0.1"
Global $_WD_PORT = 0 ; Port used for web driver communication
Global $_WD_HTTPRESULT = 0 ; Result of last WinHTTP request
Global $_WD_HTTPRESPONSE = '' ; Response of last WinHTTP request
Global $_WD_SESSION_DETAILS = "" ; Response from _WD_CreateSession
Global $_WD_BFORMAT = $SB_UTF8 ; Binary format
Global $_WD_DRIVER_CLOSE = True ; Close prior driver instances before launching new one
Global $_WD_DRIVER_DETECT = True ; Don't launch new driver instance if one already exists
Global $_WD_RESPONSE_TRIM = -1 ; Trim response string to given value for debug output
Global $_WD_ERROR_MSGBOX = False ; Shows in compiled scripts error messages in msgboxes
Global $_WD_ERROR_OUTPUTDEBUG = False ; Log errors to "OutputDebugString"
Global $_WD_DEBUG = $_WD_DEBUG_Info ; Trace to console and show web driver app
Global $_WD_CONSOLE = ConsoleWrite ; Destination for console output
Global $_WD_CONSOLE_Suffix = @CRLF ; Suffix added to the end of Message in $_WD_CONSOLE function
Global $_WD_Sleep = Sleep ; Default to calling standard Sleep function
Global $_WD_DefaultTimeout = 10000 ; 10 seconds
Global $_WD_WINHTTP_TIMEOUTS = True
Global $_WD_HTTPTimeOuts[4] = [0, 60000, 30000, 30000]
Global $_WD_HTTPContentType = "Content-Type: application/json"
Global $_WD_DetailedErrors = False
#Tidy_ILC_Pos=0
#EndRegion Global Variables
; #FUNCTION# ====================================================================================================================
; Name ..........: _WD_CreateSession
; Description ...: Request new session from web driver.
; Syntax ........: _WD_CreateSession([$sCapabilities = Default])
; Parameters ....: $sCapabilities - [optional] Requested features in JSON format. Default is '{"capabilities":{}}'
; Return values .: Success - Session ID to be used in future requests to web driver session.
; Failure - "" (empty string) and sets @error to one of the following values:
; - $_WD_ERROR_Exception
; - $_WD_ERROR_SessionNotCreated
; Author ........: Danp2
; Modified ......: mLipok
; Remarks .......:
; Related .......: _WD_DeleteSession, _WD_LastHTTPResult
; Link ..........: https://www.w3.org/TR/webdriver#new-session
; Example .......: No
; ===============================================================================================================================
Func _WD_CreateSession($sCapabilities = Default)
Local Const $sFuncName = "_WD_CreateSession"
Local $sSession = "", $sMessage = ''
If $sCapabilities = Default Then $sCapabilities = $_WD_EmptyCaps
$_WD_SESSION_DETAILS = '' ; resetting saved response details before making new request
Local $sResponse = __WD_Post($_WD_BASE_URL & ":" & $_WD_PORT & "/session", $sCapabilities)
Local $iErr = @error
Local $oJSON = Json_Decode($sResponse)
If $iErr = $_WD_ERROR_Success Then
$sSession = Json_Get($oJSON, "[value][sessionId]")
If @error Then
$sMessage = Json_Get($oJSON, $_WD_JSON_Message)
$iErr = $_WD_ERROR_Exception
Else
$sMessage = $sSession
; Save response details for future use
$_WD_SESSION_DETAILS = $sResponse
EndIf
Else
If $iErr = $_WD_ERROR_SessionNotCreated Then
$sMessage = Json_Get($oJSON, $_WD_JSON_Message)
ElseIf Not $_WD_DetailedErrors Then
$iErr = $_WD_ERROR_Exception
EndIf
EndIf
Return SetError(__WD_Error($sFuncName, $iErr, $sMessage), 0, $sSession)
EndFunc ;==>_WD_CreateSession
; #FUNCTION# ====================================================================================================================
; Name ..........: _WD_DeleteSession
; Description ...: Delete existing session.
; Syntax ........: _WD_DeleteSession($sSession)
; Parameters ....: $sSession - Session ID from _WD_CreateSession
; Return values .: Success - 1
; Failure - 0 and sets @error to $_WD_ERROR_Exception
; Author ........: Danp2
; Modified ......: mLipok
; Remarks .......:
; Related .......: _WD_CreateSession, _WD_LastHTTPResult
; Link ..........: https://www.w3.org/TR/webdriver#delete-session
; Example .......: No
; ===============================================================================================================================
Func _WD_DeleteSession($sSession)
Local Const $sFuncName = "_WD_DeleteSession"
__WD_Delete($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession)
Local $iErr = @error
If $iErr <> $_WD_ERROR_Success And Not $_WD_DetailedErrors Then $iErr = $_WD_ERROR_Exception
Local $sMessage = ($iErr) ? ('Error occurs when trying to delete session') : ('WebDriver session deleted')
Local $iReturn = ($iErr) ? (0) : (1)
Return SetError(__WD_Error($sFuncName, $iErr, $sMessage), 0, $iReturn)
EndFunc ;==>_WD_DeleteSession
; #FUNCTION# ====================================================================================================================
; Name ..........: _WD_Status
; Description ...: Get current web driver state.
; Syntax ........: _WD_Status()
; Parameters ....: None
; Return values .: Success - Dictionary object with "message" and "ready" properties.
; Failure - "" (empty string) and sets @error to $_WD_ERROR_Exception
; Author ........: Danp2
; Modified ......:
; Remarks .......:
; Related .......: _WD_LastHTTPResult
; Link ..........: https://www.w3.org/TR/webdriver#status
; Example .......: No
; ===============================================================================================================================
Func _WD_Status()
Local Const $sFuncName = "_WD_Status"
Local $sResponse = __WD_Get($_WD_BASE_URL & ":" & $_WD_PORT & "/status")
Local $iErr = @error, $oResult = ""
If $iErr = $_WD_ERROR_Success Then
Local $oJSON = Json_Decode($sResponse)
$oResult = Json_Get($oJSON, $_WD_JSON_Value)
EndIf
Return SetError(__WD_Error($sFuncName, $iErr), 0, $oResult)
EndFunc ;==>_WD_Status
; #FUNCTION# ====================================================================================================================
; Name ..........: _WD_GetSession
; Description ...: Get details on existing session.
; Syntax ........: _WD_GetSession($sSession)
; Parameters ....: $sSession - Session ID from _WD_CreateSession
; Return values .: Success - Dictionary object with "sessionId" and "capabilities" items.
; Failure - "" (empty string) and sets @error to $_WD_ERROR_Exception
; Author ........: Danp2
; Modified ......:
; Remarks .......: The Get Session functionality was added and then removed from the W3C draft spec, so the code is commented
; until they determine how this should function. See w3c/webdriver@35df53a for details. Meanwhile, I temporarily
; changed the code to return the information that is available
; Related .......: _WD_CreateSession, _WD_LastHTTPResult
; Link ..........: https://www.w3.org/TR/webdriver#get-session
; Example .......: No
; ===============================================================================================================================
Func _WD_GetSession($sSession)
Local Const $sFuncName = "_WD_GetSession"
Local $sResult
#forceref $sSession, $sFuncName
#cs See remarks in header
Local $sResponse = __WD_Get($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession)
Local $iErr = @error, $sResult = ''
If $iErr = $_WD_ERROR_Success Then
Local $oJSON = Json_Decode($sResponse)
$sResult = Json_Get($oJSON, $_WD_JSON_Value)
EndIf
__WD_ConsoleWrite($sFuncName & ": " & $sResponse, $_WD_DEBUG_Info)
If $iErr Then
Return SetError(__WD_Error($sFuncName, $_WD_ERROR_Exception), 0, $sResult)
EndIf
#ce See remarks in header
$sResult = $_WD_SESSION_DETAILS
Return SetError(__WD_Error($sFuncName, $_WD_ERROR_Success), 0, $sResult)
EndFunc ;==>_WD_GetSession
; #FUNCTION# ====================================================================================================================
; Name ..........: _WD_Timeouts
; Description ...: Set or retrieve the session timeout parameters.
; Syntax ........: _WD_Timeouts($sSession[, $sTimeouts = Default])
; Parameters ....: $sSession - Session ID from _WD_CreateSession
; $sTimeouts - [optional] Requested timouts in JSON format. Default is ""
; Return values .: Success - Return value from web driver in JSON format.
; Failure - 0 and sets @error to $_WD_ERROR_Exception
; Author ........: Danp2
; Modified ......:
; Remarks .......: Separate timeouts can be set for "script", "pageLoad", and "implicit".
; Related .......: _WD_LastHTTPResult
; Link ..........: https://www.w3.org/TR/webdriver#get-timeouts
; https://www.w3.org/TR/webdriver#set-timeouts
; Example .......: No
; ===============================================================================================================================
Func _WD_Timeouts($sSession, $sTimeouts = Default)
Local Const $sFuncName = "_WD_Timeouts"
Local $sResponse, $sURL
If $sTimeouts = Default Then $sTimeouts = ''
$sURL = $_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/timeouts"
If $sTimeouts = '' Then
$sResponse = __WD_Get($sURL)
Else
$sResponse = __WD_Post($sURL, $sTimeouts)
EndIf
Local $iErr = @error
If $iErr Then $sResponse = 0
Return SetError(__WD_Error($sFuncName, $iErr), 0, $sResponse)
EndFunc ;==>_WD_Timeouts
; #FUNCTION# ====================================================================================================================
; Name ..........: _WD_Navigate
; Description ...: Navigate to the designated URL.
; Syntax ........: _WD_Navigate($sSession, $sURL)
; Parameters ....: $sSession - Session ID from _WD_CreateSession
; $sURL - Destination URL
; Return values .: Success - 1.
; Failure - 0 and sets @error to one of the following values:
; - $_WD_ERROR_Exception
; - $_WD_ERROR_Timeout
; Author ........: Danp2
; Modified ......:
; Remarks .......:
; Related .......: _WD_LastHTTPResult
; Link ..........: https://www.w3.org/TR/webdriver#navigate-to
; Example .......: No
; ===============================================================================================================================
Func _WD_Navigate($sSession, $sURL)
Local Const $sFuncName = "_WD_Navigate"
Local Const $sParameters = 'Parameters: URL=' & $sURL
__WD_Post($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/url", '{"url":"' & $sURL & '"}')
Local $iErr = @error
Local $iReturn = ($iErr) ? (0) : (1)
Return SetError(__WD_Error($sFuncName, $iErr, $sParameters), 0, $iReturn)
EndFunc ;==>_WD_Navigate
; #FUNCTION# ====================================================================================================================
; Name ..........: _WD_Action
; Description ...: Perform various interactions with the web driver session.
; Syntax ........: _WD_Action($sSession, $sCommand[, $sOption = Default])
; Parameters ....: $sSession - Session ID from _WD_CreateSession
; $sCommand - One of the following actions:
; |
; |ACTIONS - Performs the action specified in $sOption. If $sOption = "" then all the keys and pointer buttons that are currently depressed will be released. This causes events to be fired as if the state was released by an explicit series of actions
; |BACK - Causes the browser to traverse one step backward in the joint session history of the current top-level browsing context
; |FORWARD - Causes the browser to traverse one step forwards in the joint session history of the current top-level browsing context
; |REFRESH - Causes the browser to reload the page in current top-level browsing context
; |TITLE - Returns the document title of the current top-level browsing context
; |URL - Returns the URL of the current top-level browsing context
; $sOption - [optional] a JSON string of actions to perform. Default is ""
; Return values .: Success - Return value from web driver (could be an empty string).
; Failure - "" (empty string) and sets @error to one of the following values:
; - $_WD_ERROR_Exception
; - $_WD_ERROR_InvalidDataType
; Author ........: Danp2
; Modified ......:
; Remarks .......:
; Related .......: _WD_LastHTTPResult
; Link ..........: https://www.w3.org/TR/webdriver#navigation
; https://www.w3.org/TR/webdriver#actions
; Example .......: No
; ===============================================================================================================================
Func _WD_Action($sSession, $sCommand, $sOption = Default)
Local Const $sFuncName = "_WD_Action"
Local Const $sParameters = 'Parameters: Command=' & $sCommand & ' Option=' & $sOption
Local $sResponse, $sResult = "", $iErr, $oJSON, $sURLCommand
$_WD_HTTPRESULT = 0
If $sOption = Default Then $sOption = ''
$sCommand = StringLower($sCommand)
$sURLCommand = $_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/" & $sCommand
Switch $sCommand
Case 'actions'
If $sOption <> '' Then
$sResponse = __WD_Post($sURLCommand, $sOption)
Else
$sResponse = __WD_Delete($sURLCommand)
EndIf
$iErr = @error
Case 'back', 'forward', 'refresh'
$sResponse = __WD_Post($sURLCommand, $_WD_EmptyDict)
$iErr = @error
Case 'title', 'url'
$sResponse = __WD_Get($sURLCommand)
$iErr = @error
If $iErr = $_WD_ERROR_Success Then
$oJSON = Json_Decode($sResponse)
$sResult = Json_Get($oJSON, $_WD_JSON_Value)
EndIf
Case Else
Return SetError(__WD_Error($sFuncName, $_WD_ERROR_InvalidDataType, "(Actions|Back|Forward|Refresh|Title|Url) $sCommand=>" & $sCommand), 0, "")
EndSwitch
Return SetError(__WD_Error($sFuncName, $iErr, $sParameters), 0, $sResult)
EndFunc ;==>_WD_Action
; #FUNCTION# ====================================================================================================================
; Name ..........: _WD_Window
; Description ...: Perform interactions related to the current window.
; Syntax ........: _WD_Window($sSession, $sCommand[, $sOption = Default])
; Parameters ....: $sSession - Session ID from _WD_CreateSession
; $sCommand - One of the following actions:
; |
; |CLOSE - Close current tab
; |FRAME - Switch to frame
; |FULLSCREEN - Set window to fullscreen
; |HANDLES - Get all window handles
; |MAXIMIZE - Maximize window
; |MINIMIZE - Minimize window
; |NEW - Create a new window
; |PARENT - Switch to parent frame
; |PRINT - Generate PDF representation of the paginated document
; |RECT - Get or set the window's size & position
; |RESTORE - Restore window size
; |SCREENSHOT - Take screenshot of window
; |SWITCH - Switch to designated tab
; |WINDOW - Get or set the current window
; $sOption - [optional] a string value. Default is ""
; Return values .: Success - Return value from web driver (could be an empty string).
; Failure - "" (empty string) and sets @error to one of the following values:
; - $_WD_ERROR_Exception
; - $_WD_ERROR_InvalidDataType
; Author ........: Danp2
; Modified ......: Sven Seyfert (SOLVE-SMART)
; Remarks .......:
; Related .......: _WD_LastHTTPResult
; Link ..........: https://www.w3.org/TR/webdriver/#contexts
; Example .......: No
; ===============================================================================================================================
Func _WD_Window($sSession, $sCommand, $sOption = Default)
Local Const $sFuncName = "_WD_Window"
Local Const $sParameters = 'Parameters: Command=' & $sCommand & ' Option=' & $sOption
Local Const $sRestoreParameters = '{"x": null, "y": null, "width": null, "height": null}'
Local $sResponse, $oJSON, $sResult = "", $iErr
$_WD_HTTPRESULT = 0
If $sOption = Default Then $sOption = ''
$sCommand = StringLower($sCommand)
Local $sURLSession = $_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/"
Switch $sCommand
Case 'close'
$sResponse = __WD_Delete($sURLSession & "window")
$iErr = @error
Case 'fullscreen', 'maximize', 'minimize'
$sResponse = __WD_Post($sURLSession & "window/" & $sCommand, $_WD_EmptyDict)
$iErr = @error
Case 'restore'
$sResponse = __WD_Post($sURLSession & "window/rect", $sRestoreParameters)
$iErr = @error
Case 'handles'
$sResponse = __WD_Get($sURLSession & "window/" & $sCommand)
$iErr = @error
Case 'new'
$sResponse = __WD_Post($sURLSession & "window/" & $sCommand, $sOption)
$iErr = @error
Case 'frame', 'print'
$sResponse = __WD_Post($sURLSession & $sCommand, $sOption)
$iErr = @error
Case 'parent'
$sResponse = __WD_Post($sURLSession & "frame/parent", $sOption)
$iErr = @error
Case 'rect'
If $sOption = '' Then
$sResponse = __WD_Get($sURLSession & "window/" & $sCommand)
Else
$sResponse = __WD_Post($sURLSession & "window/" & $sCommand, $sOption)
EndIf
$iErr = @error
Case 'screenshot'
If $sOption = '' Then
$sResponse = __WD_Get($sURLSession & $sCommand)
Else
$sResponse = __WD_Get($sURLSession & $sCommand & '/' & $sOption)
EndIf
$iErr = @error
Case 'switch'
$sOption = __WD_JsonHandle($sOption)
$sResponse = __WD_Post($sURLSession & "window", $sOption)
$iErr = @error
Case 'window'
If $sOption = '' Then
$sResponse = __WD_Get($sURLSession & $sCommand)
Else
$sOption = __WD_JsonHandle($sOption)
$sResponse = __WD_Post($sURLSession & $sCommand, $sOption)
EndIf
$iErr = @error
Case Else
Return SetError(__WD_Error($sFuncName, $_WD_ERROR_InvalidDataType, "(Close|Frame|Fullscreen|Handles|Maximize|Minimize|New|Parent|Print|Rect|Restore|Screenshot|Switch|Window) $sCommand=>" & $sCommand), 0, "")
EndSwitch
If $iErr = $_WD_ERROR_Success Then
Switch $sCommand
Case 'close', 'frame', 'fullscreen', 'maximize', 'minimize', 'parent', 'switch'
$sResult = $sResponse
Case 'new'
$oJSON = Json_Decode($sResponse)
$sResult = Json_Get($oJSON, "[value][handle]")
Case Else
$oJSON = Json_Decode($sResponse)
$sResult = Json_Get($oJSON, $_WD_JSON_Value)
EndSwitch
EndIf
Return SetError(__WD_Error($sFuncName, $iErr, $sParameters), 0, $sResult)
EndFunc ;==>_WD_Window
; #FUNCTION# ====================================================================================================================
; Name ..........: _WD_FindElement
; Description ...: Find element(s) by designated strategy.
; Syntax ........: _WD_FindElement($sSession, $sStrategy, $sSelector[, $sStartNodeID = Default[, $bMultiple = Default[,
; $bShadowRoot = Default]]])
; Parameters ....: $sSession - Session ID from _WD_CreateSession
; $sStrategy - Locator strategy. See defined constant $_WD_LOCATOR_* for allowed values
; $sSelector - Indicates how the WebDriver should traverse through the HTML DOM to locate the desired element(s).
; $sStartNodeID - [optional] Element ID to use as starting HTML node. Default is ""
; $bMultiple - [optional] Return multiple matching elements? Default is False
; $bShadowRoot - [optional] Starting HTML node is a shadow root? Default is False
; Return values .: Success - Element ID(s) returned by web driver.
; Failure - "" (empty string) and sets @error to one of the following values:
; - $_WD_ERROR_Exception
; - $_WD_ERROR_NoMatch
; - $_WD_ERROR_InvalidExpression
; Author ........: Danp2
; Modified ......:
; Remarks .......: An array of matching elements is returned when $bMultiple is True.
; Related .......: _WD_LastHTTPResult
; Link ..........: https://www.w3.org/TR/webdriver#element-retrieval
; Example .......: No
; ===============================================================================================================================
Func _WD_FindElement($sSession, $sStrategy, $sSelector, $sStartNodeID = Default, $bMultiple = Default, $bShadowRoot = Default)
Local Const $sFuncName = "_WD_FindElement"
Local Const $sParameters = 'Parameters: Strategy=' & $sStrategy & ' Selector=' & $sSelector & ' StartNodeID=' & $sStartNodeID & ' Multiple=' & $bMultiple & ' ShadowRoot=' & $bShadowRoot
Local $sCmd, $sBaseCmd = '', $sResponse, $sResult, $iErr = $_WD_ERROR_Success
Local $oJSON, $oValues, $sKey, $iRow, $aElements[0]
$_WD_HTTPRESULT = 0
If $sStartNodeID = Default Then $sStartNodeID = ""
If $bMultiple = Default Then $bMultiple = False
If $bShadowRoot = Default Then $bShadowRoot = False
If $sStartNodeID Then
$sBaseCmd = ($bShadowRoot) ? "/shadow/" : "/element/"
$sBaseCmd &= $sStartNodeID
; Make sure using a relative selector if using xpath strategy
If $sStrategy = $_WD_LOCATOR_ByXPath And StringLeft($sSelector, 1) <> '.' Then
$iErr = $_WD_ERROR_InvalidExpression
$sResponse = "Selector must be relative when supplying a starting element"
EndIf
EndIf
If $iErr = $_WD_ERROR_Success Then
$sCmd = '/element' & (($bMultiple) ? 's' : '')
$sSelector = __WD_EscapeString($sSelector)
$sResponse = __WD_Post($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & $sBaseCmd & $sCmd, '{"using":"' & $sStrategy & '","value":"' & $sSelector & '"}')
$iErr = @error
EndIf
If $iErr = $_WD_ERROR_Success Then
If $bMultiple Then
$oJSON = Json_Decode($sResponse)
$oValues = Json_Get($oJSON, $_WD_JSON_Value)
If UBound($oValues) > 0 Then
$sKey = "[" & $_WD_ELEMENT_ID & "]"
Dim $aElements[UBound($oValues)]
For $oValue In $oValues
$aElements[$iRow] = Json_Get($oValue, $sKey)
$iRow += 1
Next
Else
$iErr = $_WD_ERROR_NoMatch
EndIf
Else
$oJSON = Json_Decode($sResponse)
$sResult = Json_Get($oJSON, $_WD_JSON_Element)
EndIf
EndIf
Local $vResult = ($bMultiple) ? $aElements : $sResult
If $iErr Then $vResult = ""
Return SetError(__WD_Error($sFuncName, $iErr, $sParameters), 0, $vResult)
EndFunc ;==>_WD_FindElement
; #FUNCTION# ====================================================================================================================
; Name ..........: _WD_ElementAction
; Description ...: Perform action on designated element.
; Syntax ........: _WD_ElementAction($sSession, $sElement, $sCommand[, $sOption = Default])
; Parameters ....: $sSession - Session ID from _WD_CreateSession
; $sElement - Element ID from _WD_FindElement
; $sCommand - One of the following actions:
; |
; |ACTIVE - Get active element
; |ATTRIBUTE - Get element's attribute
; |CLEAR - Clear element's value
; |CLICK - Click element
; |COMPUTEDLABEL - Get element's computed label
; |COMPUTEDROLE - Get element's computed role
; |CSS - Get element's CSS value
; |DISPLAYED - Get element's visibility
; |ENABLED - Get element's enabled status
; |NAME - Get element's tag name
; |PROPERTY - Get element's property
; |RECT - Get element's dimensions / coordinates
; |SCREENSHOT - Take element screenshot
; |SELECTED - Get element's selected status
; |SHADOW - Get element's shadow root
; |TEXT - Get element's rendered text
; |VALUE - Get or set element's value. If $sOption = "" the value of the element is returned, else set
; $sOption - [optional] a string value. Default is ""
; Return values .: Success - Requested data returned by web driver.
; Failure - "" (empty string) and sets @error to one of the following values:
; - $_WD_ERROR_NoMatch
; - $_WD_ERROR_Exception
; - $_WD_ERROR_InvalidDataType
; - $_WD_ERROR_InvalidExpression
; Author ........: Danp2
; Modified ......: mLipok
; Remarks .......:
; Related .......: _WD_LastHTTPResult
; Link ..........: https://www.w3.org/TR/webdriver/#state
; https://www.w3.org/TR/webdriver#element-interaction
; https://www.w3.org/TR/webdriver/#take-element-screenshot
; https://www.w3.org/TR/webdriver/#element-displayedness
; Example .......: No
; ===============================================================================================================================
Func _WD_ElementAction($sSession, $sElement, $sCommand, $sOption = Default)
Local Const $sFuncName = "_WD_ElementAction"
; because $sOption can contain sensitive data, mask value unless $_WD_DEBUG_Full is used (refers to the case when VALUE will be set)
Local $bParameters_Option = ($_WD_DEBUG = $_WD_DEBUG_Full Or Not ($sCommand = 'VALUE' And $sOption))
Local Const $sParameters = "Parameters: Command=" & $sCommand & " Option=" & (($bParameters_Option Or Not $sOption) ? ($sOption) : ("<masked>"))
Local $sResponse, $sResult = '', $iErr, $oJSON
$_WD_HTTPRESULT = 0
If $sOption = Default Then $sOption = ''
$sCommand = StringLower($sCommand)
Local $sURLElement = $_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/element/"
Switch $sCommand
Case 'computedlabel', 'computedrole', 'displayed', 'enabled', 'name', 'rect', 'selected', 'shadow', 'screenshot', 'text'
$sResponse = __WD_Get($sURLElement & $sElement & "/" & $sCommand)
$iErr = @error
Case 'active'
$sResponse = __WD_Get($sURLElement & $sCommand)
$iErr = @error
Case 'attribute', 'css', 'property'
$sResponse = __WD_Get($sURLElement & $sElement & "/" & $sCommand & "/" & $sOption)
$iErr = @error
Case 'clear', 'click'
$sResponse = __WD_Post($sURLElement & $sElement & "/" & $sCommand, '{"id":"' & $sElement & '"}')
$iErr = @error
Case 'value'
If $sOption Then
$sResponse = __WD_Post($sURLElement & $sElement & "/" & $sCommand, '{"id":"' & $sElement & '", "text":"' & __WD_EscapeString($sOption) & '"}')
Else
$sResponse = __WD_Get($sURLElement & $sElement & "/property/value")
EndIf
$iErr = @error
Case Else
Return SetError(__WD_Error($sFuncName, $_WD_ERROR_InvalidDataType, "(Active|Attribute|ComputedRole|ComputedLabel|Clear|Click|CSS|Displayed|Enabled|Name|Property|Rect|Selected|Shadow|Screenshot|Text|Value) $sCommand=>" & $sCommand), 0, "")
EndSwitch
If $iErr = $_WD_ERROR_Success Then
Switch $sCommand
Case 'clear', 'click', 'shadow'
$sResult = $sResponse
Case 'value'
If $sOption Then
$sResult = $sResponse
Else
$oJSON = Json_Decode($sResponse)
$sResult = Json_Get($oJSON, $_WD_JSON_Value)
EndIf
Case Else
$oJSON = Json_Decode($sResponse)
$sResult = Json_Get($oJSON, $_WD_JSON_Value)
EndSwitch
EndIf
If $iErr Then $sResult = ""
Return SetError(__WD_Error($sFuncName, $iErr, $sParameters), 0, $sResult)
EndFunc ;==>_WD_ElementAction
; #FUNCTION# ====================================================================================================================
; Name ..........: _WD_ExecuteScript
; Description ...: Execute Javascipt commands.
; Syntax ........: _WD_ExecuteScript($sSession, $sScript[, $sArguments = Default[, $bAsync = Default[, $vSubNode = Default]]])
; Parameters ....: $sSession - Session ID from _WD_CreateSession
; $sScript - Javascript command(s) to run
; $sArguments - [optional] String of arguments in JSON format
; $bAsync - [optional] Perform request asyncronously? Default is False
; $vSubNode - [optional] Return the designated JSON node instead of the entire JSON string. Default is "" (entire response is returned)
; Return values .: Success - Response from web driver in JSON format or value requested by given $vSubNode
; Failure - Response from web driver in JSON format and maintains @error value originally set by __WD_Post()
; If script is executed successfully but $vSubNode isn't found, then "" (empty string) and sets @error to $_WD_ERROR_RetValue
; If $vSubNode isn't valid, then "" (empty string) and sets @error to _WD_ERROR_InvalidArgue
; Author ........: Danp2
; Modified ......: mLipok
; Remarks .......:
; Related .......: _WD_LastHTTPResult
; Link ..........: https://www.w3.org/TR/webdriver#executing-script
; Example .......: No
; ===============================================================================================================================
Func _WD_ExecuteScript($sSession, $sScript, $sArguments = Default, $bAsync = Default, $vSubNode = Default)
Local Const $sFuncName = "_WD_ExecuteScript"
Local $sResponse, $sData, $sCmd, $sMessage = ""
$_WD_HTTPRESULT = 0
If $sArguments = Default Then $sArguments = ""
If $bAsync = Default Then $bAsync = False
If $vSubNode = Default Then $vSubNode = ""
If IsBool($vSubNode) Then $vSubNode = ($vSubNode) ? $_WD_JSON_Value : "" ; True = the JSON value node is returned , False = entire JSON response is returned
If IsString($vSubNode) Then
$sScript = __WD_EscapeString($sScript)
$sData = '{"script":"' & $sScript & '", "args":[' & $sArguments & ']}'
$sCmd = ($bAsync) ? 'async' : 'sync'
$sResponse = __WD_Post($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/execute/" & $sCmd, $sData)
Local $iErr = @error
Local $oJSON = Json_Decode($sResponse)
If $iErr = $_WD_ERROR_Success Then
If StringLen($vSubNode) Then
$sResponse = Json_Get($oJSON, $vSubNode)
If @error Then
$iErr = $_WD_ERROR_RetValue
$sMessage = "Subnode '" & $vSubNode & "' not found."
EndIf
EndIf
Else
$sMessage = Json_Get($oJSON, $_WD_JSON_Message)
EndIf
Else
$iErr = $_WD_ERROR_InvalidArgue
$sResponse = ""
EndIf
Return SetError(__WD_Error($sFuncName, $iErr, $sMessage), 0, $sResponse)
EndFunc ;==>_WD_ExecuteScript
; #FUNCTION# ====================================================================================================================
; Name ..........: _WD_Alert
; Description ...: Respond to user prompt.
; Syntax ........: _WD_Alert($sSession, $sCommand[, $sOption = Default])
; Parameters ....: $sSession - Session ID from _WD_CreateSession
; $sCommand - One of the following actions:
; |
; |ACCEPT - Accept the current user prompt as if the user would have clicked the OK button
; |DISMISS - Dismiss the current user prompt as if the user would have clicked the Cancel or OK button, whichever is present, in that order
; |GETTEXT - Return the text message associated with the current user prompt or null
; |SENDTEXT - Set the text field of the current user prompt to the given value
; |STATUS - Return logical value indicating the presence or absence of an alert
; $sOption - [optional] a string value. Default is ""
; Return values .: Success - True/False or requested data returned by web driver.
; Failure - "" (empty string) and sets @error to one of the following values:
; - $_WD_ERROR_NoAlert
; - $_WD_ERROR_InvalidDataType
; Author ........: Danp2
; Modified ......: mLipok
; Remarks .......:
; Related .......: _WD_LastHTTPResult
; Link ..........: https://www.w3.org/TR/webdriver#user-prompts
; Example .......: No
; ===============================================================================================================================
Func _WD_Alert($sSession, $sCommand, $sOption = Default)
Local Const $sFuncName = "_WD_Alert"
Local Const $sParameters = 'Parameters: Command=' & $sCommand & ' Option=' & $sOption
Local $sResponse, $iErr, $oJSON, $sResult = ''
$_WD_HTTPRESULT = 0
If $sOption = Default Then $sOption = ''
$sCommand = StringLower($sCommand)
Local $sURLSession = $_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/"
Switch $sCommand
Case 'accept', 'dismiss'
$sResponse = __WD_Post($sURLSession & "alert/" & $sCommand, $_WD_EmptyDict)
$iErr = @error
Case 'gettext'
$sResponse = __WD_Get($sURLSession & "alert/text")
$iErr = @error
If $iErr = $_WD_ERROR_Success Then
$oJSON = Json_Decode($sResponse)
$sResult = Json_Get($oJSON, $_WD_JSON_Value)
EndIf
Case 'sendtext'
$sResponse = __WD_Post($sURLSession & "alert/text", '{"text":"' & $sOption & '"}')
$iErr = @error
Case 'status'
$sResponse = __WD_Get($sURLSession & "alert/text")
$iErr = @error
$sResult = ($iErr = $_WD_ERROR_NoAlert) ? False : True
If $iErr = $_WD_ERROR_NoAlert Then $iErr = $_WD_ERROR_Success
Case Else
Return SetError(__WD_Error($sFuncName, $_WD_ERROR_InvalidDataType, "(Accept|Dismiss|GetText|SendText|Status) $sCommand=>" & $sCommand), 0, "")
EndSwitch